Question

I have added hints to components on my form. When the components receive the focus, I’d like to set the caption of a label component to display the hint.

I have added a TApplicationEvents object and set the OnShowHint event to

procedure TImportFrm.ApplicationEvents1ShowHint(var HintStr: string;
  var CanShow: Boolean; var HintInfo: THintInfo);
begin
  HelpLbl.Caption := HintStr;
end;

However it seems that the ShowHint event only fires with mouse movements. Is there a way to fire the hint code when components receive focus, without having to implement the OnEnter event for every single component on the form?

Answer 1

Add a handler for TScreen.OnActiveControlChange in your main form’s creation, and handle the hints in that event:

type
  TForm2=class(TForm)
  ...
  private
    procedure ScreenFocusControlChange(Sender: TObject);
  end;

implementation

procedure TForm2.FormCreate(Sender: TObject);
begin
  Screen.OnActiveControlChange := ScreenFocusControlChange;
end;

procedure TForm2.ScreenFocusControlChange(Sender: TObject);
begin
  Label1.Caption := ActiveControl.Hint;
  Label1.Update;
end;

Note that Sender won’t do you much good; it’s always Screen. You can filter (for instance, to only change the Label.Caption for edit controls) by testing the ActiveControl:

if (ActiveControl is TEdit) then
  // Update caption of label with ActiveControl.Hint

Note that if you’ll need to reassign the event when you show child forms (to an event on that child form), or you’ll always be updating the original form’s label with the hints. The easiest way to do the reassignment is to give every form an OnActiveControlChange handler, and assign it in the form’s OnActivate event and unassign it in the OnDeactivate event:

procedure TForm1.FormActivate(Sender: TObject);
begin
  Screen.OnActiveControlChange := Self.ScreenActiveControlChange;
end;

procedure TForm1.FormDeactivate(Sender: TObject);
begin
  Screen.OnActiveControlChange := nil;
end;

This will allow you to update controls other than Label1 on each form, and only use the hint changes on forms you want to do so.