Question

I have an application that executes a stored procedure. There is a combo box “City” and the user that can select only one value and I use that value as an SQL parameter in My C# code.

Simplified Example :

Select StudentName, Age 
From dbo.Students
Where City = @city

@city is replaced by the value from the combo box.

Now the requirement is changed and the combo box supports multiple selection. The selected elements are stored in an array. Now I am using the following approach.

1. Use String.Join(“‘,'”) and join the array elements and the result is assigned to @city.

2. Changing the query to use IN operator.

   Select StudentName, Age
From dbo.Students
Where City IN (@city)

Suppose the selected cities are London and Sydney then @City becomes London’,’Sydney. Then in SP it will be used as ‘London’,’Sydney’ which is syntactically correct. But this query fails.

What do I do incorrectly?
What is the best (Nice) approach to handle this?

Answer 1

The way you want to use IN is incorrect, it doesn’t work that way.

Options:

1. send a CSV string to the SP then split it and create a temporary dataset (table variable for instance) with which you will then do a JOIN
2. dynamic SQL

Example split function:

CREATE FUNCTION [dbo].[Split](
    @String nvarchar (4000),
    @Delimiter nvarchar (10)
 )
RETURNS @ValueTable TABLE ([Value] nvarchar(4000), [ElementsCount] int)
BEGIN
     DECLARE @nextString nvarchar(4000)
     DECLARE @pos int
     DECLARE @nextPos int
     DECLARE @commaCheck nvarchar(1)
     DECLARE @elementsCount int

     SET @elementsCount = 0

     --Initialize
     SET @nextString = ''
     SET @commaCheck = RIGHT(@string, 1) 

     --Check for trailing Comma, if not exists, INSERT
     SET @string = @string + @delimiter

     --Get position of first Comma
     SET @pos = CHARINDEX(@delimiter, @string)
     SET @nextPos = 1

     --Loop while there is still a comma in the String of levels
     WHILE (@pos <>  0)  
     BEGIN
          SET @nextString = SUBSTRING(@string, 1, @pos - 1)

          INSERT INTO @ValueTable ([Value]) VALUES (@nextString)

          SET @string = SUBSTRING(@string, @pos +1, LEN(@string))

          SET @nextPos = @pos
          SET @pos = CHARINDEX(@delimiter, @string)

          SET @elementsCount = @elementsCount + 1
     END

     UPDATE @ValueTable SET [ElementsCount] = @elementsCount

     RETURN
END

And then you use it like so:

SELECT
    StudentName, Age
FROM
    dbo.Students
    JOIN [dbo].[Split](@city, ',') Cities ON City = Cities.Value