Question

I have an application that I can load an image through a URLLoader and pop it into a movie clip and display that movie clip.

I need to then be able to write that image into an xml file so that I can re-load the image if needed.

I am currently loading the image, and then storing it as BitmapData via something along the lines of:

var decodedBitmapData:BitmapData = Bitmap(image).bitmapData;
backgroundImageBitmapData = decodedBitmapData;

And then I do something along the following lines to write it into an xml file. The data is stored in an object that is stored in an array called aRooms. (Which is the above “backgroundImageBitmapData”.)

var tempImage:Bitmap = new Bitmap(aRooms[i].backgroundImageData);
var bytes:ByteArray = tempImage.bitmapData.getPixels(tempImage.bitmapData.rect);
var roomBG:XML = new XML( <bg> { String(bytes) } </bg>);

That roomBG (XML) variable is then appended to the full XML file that I am exporting.

From there, I need to read that xmllist and convert it to, I think, bitmapdata so I can load it via a loader. But that’s where I am stuck.

It is possible that I am saving it wrong as well, so if that is the case, all help and corrections are welcome.

Thanks.

Answer 1

If I understand your question correctly. You would like to have a string representation
of the byte array. You could achieve this by having it base64 encoded. You can download the libs here.

Then you would have something like this:

var rect:Rectangle = new Rectangle(0,0,myImage.width,myImage.height);
var byteArray:ByteArray = myImage.bitmapData.getPixels(rect);

//to encode to a string
var encoded:String = Base64.encodeByteArray(byteArray);

//to decode the string 
var decoded:ByteArray = Base64.decodeToByteArray(encoded);
decoded.position = 0;

var newBitmapData:BitmapData = new BitmapData(rect.width,rect.height,true,0xFFFFFFFF);
newBitmapData.setPixels(rect, decoded);

var newImage:Bitmap = new Bitmap(newBitmapData, "auto", true);