Question

I have an AWK script which looks like

#!/usr/bin/gawk -f

BEGIN { print myVar; }
{ print; }

which I can run locally in a Unix shell via the command

./myScript.awk -v myVar=value /tmp/inputfile

It correctly prints “value” and then dumps the inputfile.

I set up an apache web server with CGI enabled and created the following myScript.cgi:

#!/usr/bin/gawk -f

BEGIN {
    print "Content-type: text/plain";
    print "";
    print myVar;
}
{ print; }

I can run it by pointing my web browser to

http://localhost/cgi-bin/myScript.cgi?/tmp/inputfile

but how can I pass the “-v myVar=value” bit through the URL?

Answer 1

You cannot pass a ‘-v’ variable through the CGI interface. The only way to access information is via a number number of environment variables that the CGI interface sets for you. You can access these in awk through the ENVIRON array. You are probably mostly interested in the QUERY_STRING variable, so try this:

#!/usr/bin/gawk -f
BEGIN {
    print "Content-type: text/plain"
    print ""
    print ENVIRON["QUERY_STRING"]
}
1

When accessed as http://localhost/cgi-bin/myScript.cgi?myVar=foo&otherVar=bar, ENVIRON["QUERY_STRING"] will contain myVar=foo&otherVar=bar. You will have to process this string yourself to extract your variables. For example (untested):

BEGIN {
    split(ENVIRON["QUERY_STRING"], a, "&")
    for (i in a) {
        if (a[i] ~ /^myVar=/) {
            split(a[i], tmp, "=")
            myVar=tmp[2]
        }
    }
}