Question

I have an embedded system that serves JSON results via a CGI process. I’m trying to setup a Flex app. to periodically poll the server once per second and update the GUI. I’m trying the approach below using a timer, but I only get the initial result, subsequent updates are not made. What could be going wrong?

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
               xmlns:s="library://ns.adobe.com/flex/spark" 
               xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="955" minHeight="600"
               creationComplete="application1_creationCompleteHandler(event)">
    <fx:Declarations>
        <!-- Place non-visual elements (e.g., services, value objects) here -->
        <mx:HTTPService id="getPacketCounts" showBusyCursor="true" resultFormat="text" 
                        url="http://10.1.10.28/cgi-bin/getpacketcounts" 
                        requestTimeout="500"
                        result="getPacketCounts_resultHandler(event)"
                        fault="faultHandler(event)">
        </mx:HTTPService>       
    </fx:Declarations>
    <fx:Script>
        <![CDATA[
            import mx.controls.Alert;
            import mx.events.FlexEvent;
            import mx.rpc.events.FaultEvent;
            import mx.rpc.events.ResultEvent;
            private var timer:Timer = new Timer(1000, 0);
            private var counter:int;

            protected function application1_creationCompleteHandler(event:FlexEvent):void
            {
                timer.addEventListener(TimerEvent.TIMER, timerListener);
                timer.start();
            }

            private function timerListener(evt:Event):void {
                label.text = "get http://10.1.10.28/cgi-bin/getpacketcounts";
                getPacketCounts.send();
            }

            protected function getPacketCounts_resultHandler(event:ResultEvent):void
            {
                label.text = event.result.toString().substr(0, 60);
            }           

            protected function faultHandler(event:FaultEvent):void
            {
                Alert.show("The server returned error code " + event.statusCode + ".", event.fault.faultString);
            }               
        ]]>
    </fx:Script>
    <s:Label id="label" text="v1.0"/>
</s:Application>

Answer 1

I can’t see anything glaringly wrong with your code though I suspect the problem lies with your Timer getting out of sync with your HTTPService. Your Timer fires every second but it might take longer for your HTTPService to return a result and the next tick of your Timer tramples over the previous getPacketCounts.send() request. I’m not 100% sure about this though.

If I were writing this app I’d set it up so the Timer fired once, reset the Timer, sent of the HTTPService request, then waiting for a response before restarting the Timer.

   // Make the Timer run once.
   private var timer:Timer = new Timer(1000, 1);

   // ....

   // Add listeners to the Timer and start it
   protected function application1_creationCompleteHAndler(event:FlexEvent):void
   {
       timer.addEventListener(TimerEvent.TIMER_COMPLETE, timerListener);
       timer.start();
   }

   // Send the request
   private function timerListener(e:TimerEvent):void
   {
       timer.reset();
       // Your other stuff
   }

   protected function getPacketCounts_resultHandler(event:ResultEvent):void
   {
       timer.start()
       // Your code
   }           

   protected function faultHandler(event:FaultEvent):void
   {
       timer.start()
       // Your code
   }