Question

I have an excel sheet that looks like this

data1 data2 data3 ... data10
 ...   ...   ...  ...  ...
dataX dataY dataZ ... dataN

I need to somhow “flatten” the data into one single column like this:

data1
data2
data3
 ...
data10
dataX
dataY
dataZ
 ...
dataN

I tried creating a macro that would automate a copy+paste process starting from a selection. Here’s my code:

Sub copyIn1Col()
'
' copyIn1Col Macro
'
' Keyboard Shortcut: Ctrl+r
'
    Selection.copy
    Range("B31").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Range("D3:D13").Select
End Sub

The problem with that is that it overwrites the copied selection to the same range.

Answer 1

The most simplest and fastest would be to use arrays. I am assuming the following

1. The data is in Sheet1 from range A1 to E15
2. You want the output in Sheet2 Cell A1

Hope this is what you want?

Option Explicit

Sub Sample()
    Dim inPutR, outPut()
    Dim i As Long, j As Long, n As Long

    '~~> Change this to the respective range
    inPutR = ThisWorkbook.Sheets("Sheet1").Range("A1:E15")

    ReDim Preserve outPut(UBound(inPutR, 1) * UBound(inPutR, 2))

    For i = LBound(inPutR, 1) To UBound(inPutR, 1)
        For j = LBound(inPutR, 2) To UBound(inPutR, 2)
            outPut(n) = inPutR(i, j)
            n = n + 1
        Next j
    Next i

    ThisWorkbook.Sheets("Sheet2").Range("A1").Resize(UBound(outPut) + 1) = _
    Application.Transpose(outPut)
End Sub