Question

I have an NSIS installer script that I’m using to deploy a py2exe-built app (using NSIS 2.46). The only UI detail I can’t iron out is the window title on the installer.

According to the docs, the Caption directive should set this text. But whatever I set, it always has the text “: Installing” appended to it. That is, if I have:

Caption "My Special App"

…then the window title on the installer shows “My Special App: Installing”. How do I get around this?

(I want to avoid this because I’m actually using the NSIS installer to extract the app to a temporary directory and run it once, not to permanently install it.)

My entire NSI file is:

!define py2exeOutputDirectory 'C:\Path\To\P2EOutput'
!define exe 'MyApp.exe'

; Comment out the "SetCompress Off" line and uncomment
; the next line to enable compression. Startup times
; will be a little slower but the executable will be
; quite a bit smaller
;SetCompress Off
SetCompressor /SOLID lzma

Caption "My Special App"

Name 'MyApp'
OutFile ${exe}
Icon 'C:\Path\To\Icon\icon.ico'

;SilentInstall silent
AutoCloseWindow true
ShowInstDetails nevershow

Section
    DetailPrint "Extracting program..."
    SetDetailsPrint none

    InitPluginsDir
    SetOutPath '$PLUGINSDIR'
    File /r '${py2exeOutputDirectory}\*'

    GetTempFileName $0
    ;DetailPrint $0
    Delete $0
    StrCpy $0 '$0.bat'
    FileOpen $1 $0 'w'
    FileWrite $1 '@echo off$\r$\n'
    StrCpy $2 $TEMP 2
    FileWrite $1 '$2$\r$\n'
    FileWrite $1 'cd $PLUGINSDIR$\r$\n'
    FileWrite $1 '${exe}$\r$\n'
    FileClose $1
    HideWindow
    nsExec::Exec $0
    Delete $0
SectionEnd

Answer 1

SubCaption 3 " "

or

PageEx InstFiles
        Caption " "
PageExEnd

or

LangString "^InstallingSubCaption" 0 " "