Question

I have an oracle procedure which calls few other procedures.

PROCEDURE1

PROCEDURE2
PROCEDURE3
..

Now what happens is that PROCEDURE2 is performing DDL (EXECUTE IMMEDIATE 'DDL PROCESS' ) on some dependent tables being used in subsequent procedures 3 and onwards. This runs fine until it hits PROCEDURE3 where it throws ORA-06508 - Program / Unit being called not found.

We can not modify it not to use DDL, We have to use them. I have tried recompiling after DDL statements but it does not work (ALTER PROCEDURE PROCEDURE3 RECOMPILE) neither in PROCEDURE1 or in PROCEDURE2.

I doubt that PROCEDURE1 itself becomes invalid and compiling that on runtime will cause endless loop. I have tried, does not works.

So I need to use some trick that can make these procedures valid again on runtime after DDL is done on dependent objects.

Thanks in advance for whoever participates to answer.

Answer 1

In this case, as in many other cases, would be better to create a package instead of a bunch of stand-alone procedures. Packages break dependency chain. Here is an example:

    SQL> create table tb_t(
     2    col1 number
     3  )
     4  ;

    Table created

1. Stand-alone procedures

   SQL> create or replace procedure Proc1
     2  is
     3  begin
     4    execute immediate 'alter table tb_t add (col2 number)';
     5  end;
     6  /
   

   Procedure created

   SQL> create or replace procedure Proc2
    2  is
    3    l_var number;
    4  begin
    5    select count(*)
    6      into l_var
    7      from tb_t;
    8    dbms_output.put_line(to_char(l_var));
    9  end;
    10  /
   
    Procedure created
   
    SQL> begin
     2    proc1;
     3    proc2;
     4  end;
     5  /
   

and we are getting

     ORA-06508: PL/SQL: could not find program unit being called

1. Package

   SQL> create or replace package test_pkg
     2  is
     3    procedure proc1;
     4    procedure proc2;
     5  end;
     6  /
   
   Package created
   
   SQL> create or replace package body test_pkg
     2  is
     3    procedure proc1
     4    is
     5    begin
     6      execute immediate 'alter table tb_t add (col3 number)';
     7    end;
     8  
     9    procedure proc2
    10    is
    11     l_var number;
    12    begin
    13      select count(*)
    14        into l_var
    15        from tb_t;
    16      dbms_output.put_line(to_char(l_var));
    17    end;
    18  
    19  end;
    20  /
   
    Package body created
   
   
    SQL> begin
      2    test_pkg.proc1;
      3    test_pkg.proc2;
      4  end;
      5  /
   
      0
   
      PL/SQL procedure successfully completed