Question

I have an XML file which is supposed to be my phones contacts backup and I am trying to create a php file to retrieve only the contacts that have a phone number assigned to them. The file contains contacts from different applications.

The XML has these elements:

<Contact>
    <Id>5238</Id>
    <GivenName>friend1</GivenName>
    <FullName>friendA</FullName>
    <CreateTime>0001-01-01T00:00:00+00:00</CreateTime>
    <ModifyTime>0001-01-01T00:00:00+00:00</ModifyTime>
    <Starred>false</Starred>
    <AccountName>SIM</AccountName>
    <AccountType>com.anddroid.contacts.sim</AccountType>
  </Contact>

<PhoneNumbers>
    <Id>53</Id>
    <ContactId>1380</ContactId>
    <Name>2</Name>
    <Value>07123456789</Value>
    <Primary>2</Primary>
  </PhoneNumbers>

<Contact>
    <Id>328</Id>
    <FamilyName>tee</FamilyName>
    <GivenName>friend2</GivenName>
    <FullName>friend2 tee</FullName>
    <CreateTime>0001-01-01T00:00:00+00:00</CreateTime>
    <ModifyTime>0001-01-01T00:00:00+00:00</ModifyTime>
    <Picture>18948</Picture>
    <Starred>false</Starred>
    <AccountName>[e-mail]</AccountName>
    <AccountType>com.htc.socialnetwork.facebook</AccountType>
  </Contact>

And I want to make a php file that will retrieve the FullName from Contact and the Value from PhoneNumbers where the Contact/Id matches the PhoneNumbers/ContactId.

I created this code:

<?php
$xml = simplexml_load_file("Contact.xml");

$i=0;
$k=0;
foreach ($xml->Contact as $contact) {
    if ($contact->AccountName == "SIM"){

   echo "Contact:   " . $k . "<br />   "; echo $contact->nodeValue[$k] . "<br />   " . $contact->FullName . "<br />   ";
   $k++;
   }
   }
   foreach ($xml->PhoneNumbers as $number) {

    echo "Contact:   " . $i . "<br />   "; echo  $number->Value . "<br />   ";
   $i++;
    }

?>

It outputs 53 contacts and 173 numbers. If I dont put the if ($contact->AccountName == "SIM") it outputs the same numbers but 700++ contacts. I just want some help producing a function or something to output only the contacts that I already have their phone number.

Any help is appreciated.

Thank you

Answer 1

I would suggest to use a XSL-stylesheet:

<xsl:stylesheet version="1.0"
            xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >

<xsl:template match="/">
  <ul><xsl:apply-templates/></ul>
</xsl:template>

<xsl:template match="Contact"> 
  <!-- select phonenumbers with the matching ContactId -->
  <xsl:variable name="numbers" select="//PhoneNumbers[ContactId=current()/Id]"/>

  <!-- when any matching  PhoneNumber has been found, continue -->
  <xsl:if test="count($numbers) &gt; 0">
  <li>
    <xsl:value-of select="FullName"/>
    <ul>
      <!-- call a named template with the matching PhoneNumbers as param -->
      <xsl:call-template name="printNumbers">
        <xsl:with-param name="numbers" select="$numbers" />
      </xsl:call-template>
    </ul>
  </li>
  </xsl:if>
</xsl:template>

<xsl:template name="printNumbers">
  <xsl:param name="numbers" />
  <!-- loop through PhoneNumbers and print the Value -->
  <xsl:for-each select="$numbers">
    <li><xsl:value-of select="Value" /></li>
  </xsl:for-each>
</xsl:template>

<xsl:template match="PhoneNumbers"/>
</xsl:stylesheet> 

How to use the stylesheet:

<?php

$doc = new DOMDocument();
$xsl = new XSLTProcessor();

$doc->load('path/to/stylesheet.xsl');
$xsl->importStyleSheet($doc);

$doc->load('Contact.xml');
echo $xsl->transformToXML($doc);

?>