Question

I have an XML file with the following structure:

<block1>
 <node>
  <name>A<name/>
 <node/>
 <node>
  <name>B<name/>
 <node/>
 ...
</block1>

<block2>
 <node>
  <name>B<name/>
 <node/>
 <node>
  <name>D<name/>
 <node/>
 ...
</block2>

The entrees of each block are sorted based on the name.

I want to create a table that will hold all of the names that belong in block1 and block2.
How can I do this efficiently (using the fact that the nodes are sorted)?

Answer 1

A solution using keys:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kB1NodeByVal" match="block1/node" use="name"/>
 <xsl:key name="kB2NodeByVal" match="block2/node" use="name"/>

 <xsl:variable name="vDistinctB1Nodes" select=
 "/*/block1/node
      [generate-id()
      =
       generate-id(key('kB1NodeByVal',name)[1])
       ]"/>

 <xsl:template match="/">
     <xsl:copy-of select="$vDistinctB1Nodes[key('kB2NodeByVal', name)]"/>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the (corrected from severe malformedness) provided XML document:

<t>
    <block1>
        <node>
            <name>A</name>
        </node>
        <node>
            <name>B</name>
        </node>
 ...
    </block1>
    <block2>
        <node>
            <name>B</name>
        </node>
        <node>
            <name>D</name>
        </node>
 ...
    </block2>
</t>

the wanted, correct result is produced:

<node>
   <name>B</name>
</node>

The efficiency of this solution is O(k), where k is the number of distinct values in Set 1. This assumes that we have already constructed the keys (indexes) and the set of distinct values in Set 1.