Question

I have an xml like this:

<xml>
    <node name="1">node1</node>
    <node name="2">node2</node>
    <node name="3">node3</node>
    <node>node4</node>
</xml>

How do I check that <node name="3">node3</node> is the last node with a @name attribute?

Answer 1

You could make use of the following-sibling operator here. Assuming you were positioned on a node elemenet, you just need to check the current node has an name attribute but no following-sibling does

<xsl:if test="@name and not(following-sibling::node[@name])">

This could also be done as part of a template match

<xsl:template match="node[@name][not(following-sibling::node[@name])]">

For example, try the following XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="node[@name][not(following-sibling::node[@name])]">
        <xsl:copy>
                <xsl:attribute name="last">1</xsl:attribute>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

When applied to your XML, the following is output

<xml>
   <node name="1">node1</node>
   <node name="2">node2</node>
   <node last="1" name="3">node3</node>
   <node>node4</node>
</xml>

EDIT: Actually, in a template match, you could make use of last here. The following template match should also work.

<xsl:template match="node[@name][last()]">