Question

I have an XML Schema that contains the following type element:

<xs:simpleType name="value">
  <xs:union memberTypes="xs:boolean xs:int xs:double xs:string"/>
</xs:simpleType>

A sample XML fragment would be:

<value>42</value>

In an XSLT transform, how do I determine which type the value has, i.e., is it a boolean, an integer, a double, or a string?

Answer 1

In an XSLT transform, how do I determine which type the value has,
i.e., is it a boolean, an integer, a double, or a string?

If there isn’t a schema associated with the XML document, the answer is that the type is always xs:string and the question isn’t too meaningful.

However, the correct question is: With which of those types is this compatible (castable as) ?

This transformation shows how this can be found out. It also illustrates the elegance and power of <xsl:next-match>:

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()[. castable as xs:integer]">
     <xsl:sequence select="., ' is castable as xs:integer. '"/>
     <xsl:next-match/>
 </xsl:template>

 <xsl:template match="text()[. castable as xs:boolean]">
     <xsl:sequence select="., ' is castable as xs:boolean. '"/>
     <xsl:next-match/>
 </xsl:template>

 <xsl:template match="text()[. castable as xs:string]">
     <xsl:sequence select="., ' is castable as xs:string. '"/>
     <xsl:next-match/>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

when applied on the provided XML document:

<value>42</value>

the wanted, correct result is produced:

42 is castable as xs:string. 42 is castable as xs:integer.