Question

I have an XML structure like the following:

<Page Depth="1">
  <Page Title="Communities" Depth="2">
    <Page Title="Blog" iscurrent="true" Depth="3"/>
    <Page Title="Something" Depth="3"/>
    <Page Title="Anything" Depth="3"/>
  </Page>
  <Page Title="News" Depth="2">
    <Page Title="Archived news" Depth="3"/>
  </Page>
</Page>

I have put this into an XML Variable called sitemap

I’m struggling with XPATH that would return the parent node of the node with the @iscurrent attribute along with its children. So from the example above, I need the following subset:

<Page Title="Communities" Depth="2">
  <Page Title="Blog" iscurrent="true" Depth="3"/>
  <Page Title="Something" Depth="3"/>
  <Page Title="Anything" Depth="3"/>
</Page>

I have tried applying this template, but nothing gets output:

<xsl:apply-templates mode="Tabs" 
        select="$sitemap/Page[@iscurrent='true']/parent/*" />

The template shouldn’t be relevant, but anyhow, here is a basic version of it:

<xsl:template mode="Tab" match="*">
  <li>
      <xsl:if test="@iscurrent = 'true'">
        <xsl:attribute name="class">current</xsl:attribute>
      </xsl:when>
    <xsl:value-of select="@MenuTitle" />
  </li>
</xsl:template>

Answer 1

You want something that selects the Page element having a child Page whose iscurrent attribute equals true:

$sitemap/Page[Page[@iscurrent='true']]

Demonstration:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="sitemap" select="/Page" />
    <xsl:template match="/">
        <xsl:apply-templates select="$sitemap/Page[Page[@iscurrent='true']]" />
    </xsl:template>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

On this input:

<Page Depth="1">
    <Page Title="Communities" Depth="2">
        <Page Title="Blog" iscurrent="true" Depth="3" />
        <Page Title="Something" Depth="3" />
        <Page Title="Anything" Depth="3" />
    </Page>
    <Page Title="News" Depth="2">
        <Page Title="Archived news" Depth="3" />
    </Page>
</Page>

Output:

<Page Title="Communities" Depth="2">
    <Page Title="Blog" iscurrent="true" Depth="3" />
    <Page Title="Something" Depth="3" />
    <Page Title="Anything" Depth="3" />
</Page>