Question

I have another XSLT question which follows on from the question I asked last week.
XSL for Xml to table transformation for two rows and many columns.

The challenges is to insert different classes for each according to the section attribute. And I need two different outputs as hown in the output below. I have an example XSLT from my previous question, which I want to edited accordingly.

Please note I’m working with XSLT 1.0. Any advice or guidance will be much appreciate.

Input:

<root>
  <page number="1" section="Arsenal">Arsenal</page> 
  <page number="2" section="Arsenal">Arsenal</page> 
  <page number="3" section="Arsenal">Arsenal</page> 
  <page number="4" section="Arsenal">Arsenal</page> 
  <page number="5" section="Arsenal">Arsenal</page> 
  <page number="6" section="Arsenal">Arsenal</page> 
  <page number="7" section="Chelsea">Chelsea</page> 
  <page number="8" section="Chelsea">Chelsea</page> 
  <page number="9" section="Chelsea">Chelsea</page> 
  <page number="10" section="Chelsea">Chelsea</page> 
  <page number="11" section="Chelsea">Chelsea</page> 
  <page number="12" section="Chelsea">Chelsea</page> 
  <page number="13" section="ManUnited">ManUnited</page> 
  <page number="14" section="ManUnited">ManUnited</page> 
  <page number="15" section="ManUnited">ManUnited</page> 
  <page number="16" section="ManUnited">ManUnited</page> 
  <page number="17" section="ManUnited">ManUnited</page> 
  <page number="18" section="ManUnited">ManUnited</page> 
  <page number="19" section="ManCity">ManCity</page> 
  <page number="20" section="ManCity">ManCity</page> 
  <page number="21" section="ManCity">ManCity</page> 
  <page number="22" section="ManCity">ManCity</page> 
  <page number="23" section="ManCity">ManCity</page> 
  <page number="24" section="ManCity">ManCity</page> 
 </root>

Output 1:

<table>
<tr>
<td class="AFC">Arsenal</td>
<td></td>
<td class="CFC">Chelsea</td>
<td></td>
<td class="MUFC">ManUnited</td>
<td></td>
<td class="MCFC">ManCity</td>
<td></td>
</tr>
<tr>
<td>1</td>
<td>6</td>
<td>7</td>
<td>12</td>
<td>13</td>
<td>18</td>
<td>19</td>
<td>24</td>
</tr>
</table>

Output 2:

<table>
<tr>
<td class="Arsenal">Arsenal</td>
<td></td>
<td class="Chelsea">Chelsea</td>
<td></td>
<td class="ManUnited">ManUnited</td>
<td></td>
<td class="ManCity">ManCity</td>
<td></td>
</tr>
<tr>
<td>1</td>
<td>6</td>
<td>7</td>
<td>12</td>
<td>13</td>
<td>18</td>
<td>19</td>
<td>24</td>
</tr>
</table>

Current XSLT provide by @Kirill Polishchuk

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>
<xsl:key name="k" match="page" use="@section"/>

<xsl:template match="/root">
<table>
<tr>
<xsl:apply-templates select="page[generate-id() = generate-id(key('k', @section))]"/>
</tr>
<tr>
<xsl:apply-templates select="page[generate-id() = generate-id(key('k', @section))]" mode="page"/>
</tr>
</table>
</xsl:template>

<xsl:template match="page">
<td>
<xsl:value-of select="."/>
</td>
<td></td>
</xsl:template>

<xsl:template match="page" mode="page">
<td>
<xsl:value-of select="@number"/>
</td>
<td>
<xsl:value-of select="key('k', @section)[last()]/@number"/>
</td>
</xsl:template>

</xsl:stylesheet>

Answer 1

Use this XSLT:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:my="my">
  <xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>

  <xsl:key name="k" match="page" use="@section"/>

  <xsl:param name="short-name" select="true()"/>
  <!-- Change param to false()-->

  <my:data>
    <club name="Arsenal">AFC</club>
    <club name="Chelsea">CFC</club>
    <club name="ManUnited">MUFC</club>
    <club name="ManCity">MCFC</club>
  </my:data>

  <xsl:template match="/root">
    <table>
      <tr>
        <xsl:apply-templates select="page[generate-id() = generate-id(key('k', @section))]"/>
      </tr>
      <tr>
        <xsl:apply-templates select="page[generate-id() = generate-id(key('k', @section))]" mode="page"/>
      </tr>
    </table>
  </xsl:template>

  <xsl:template match="page">
    <xsl:variable name="class">
      <xsl:choose>
        <xsl:when test="$short-name">
          <xsl:value-of select="document('')/*/*/club[@name = current()/@section]"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="@section"/>
        </xsl:otherwise>
      </xsl:choose>

    </xsl:variable>

    <td class="{$class}">
      <xsl:value-of select="."/>
    </td>
    <td></td>
  </xsl:template>

  <xsl:template match="page" mode="page">
    <td>
      <xsl:value-of select="@number"/>
    </td>
    <td>
      <xsl:value-of select="key('k', @section)[last()]/@number"/>
    </td>
  </xsl:template>

</xsl:stylesheet>

Depending on parameter $short-name it renders your 1^st desired XML or 2^nd.