Question

I have been trying to write a Perl script that would check the service status of Remote Servers. I am using the Win32::Service module to accomplish my goal.

I find that the for some services value returned by Win32::Service::GetStatus CurrentStatus is not exactly the same as observed from services.msc applet.

Here is the piece of script I am using along with both outputs from script and servics.msc.

use Data::Dumper;
use Win32;
use Win32::Service;
use strict;
use warnings;

my %statcodeHash = (     '1' => 'stopped.',
                     '2' => 'start pending.',
                     '3' => 'stop pending.',
                     '4' => 'running.',
                     '5' => 'continue pending.',
                     '6' => 'pause pending.',
                     '7' => 'paused.'            );


my @serviceNames = qw(NNMAction RpcEptMapper smstsmgr SNMPTRAP);

foreach my $serv (@serviceNames)
{   my %status;
    my $ret = Win32::Service::GetStatus('nnmi.hclt.corp.hcl.in', $serv, \%status);
    if ($ret)
    {   print "success\t$statcodeHash{$status{CurrentState}}\t$serv\n";
    }
    else
    {       print Win32::FormatMessage(Win32::GetLastError()), "\n";
    }
}

OUTPUT from Script

D:\AVI MEHENWAL\PERL\SCRIPTS\PROJECTS\Serve Management>perl -w perl_RemoteServiceStatus.pl
success stopped.        NNMAction
success running.        RpcEptMapper
success stopped.        smstsmgr
success stopped.        SNMPTRAP

OUTPUT from Services.msc

Name       Descrition   Status   StartupType  LogOnAs
NNMAction  bla bla bla  Started  Manual       LocalSystem

Can anyone suggest me what approach should I follow to achieve my goal, Is my method wrong or there is something I am missing from Perl module point of view?

Answer 1

Updated

I noticed that nnmi.hclt.corp.hcl.in seems to be a domain name rather than a Windows style machine name. First, find out the IP address corresponding to nnmi.hclt.corp.hcl.in. Let’s say it is x.x.x.x.

Now, run nbtstat -A x.x.x.x. That should tell you the name of the machine. Let’s say it is NNMI. Then, you should specify that in the my $remote line below, replacing MYREMOTE with NNMI, and try again.

I am assuming you have the correct privileges etc. If you get an authorization related error, I am afraid I cannot help you, but you can ask on ServerFault to find out what you need to do so as to be able to query services on a remote machine in the domain.

use strict;
use warnings;
use Data::Dumper;
use Win32;
use Win32::Service;

my %status_codes = reverse (
    SERVICE_STOPPED          => 0x00000001,
    SERVICE_START_PENDING    => 0x00000002,
    SERVICE_STOP_PENDING     => 0x00000003,
    SERVICE_RUNNING          => 0x00000004,
    SERVICE_CONTINUE_PENDING => 0x00000005,
    SERVICE_PAUSE_PENDING    => 0x00000006,
    SERVICE_PAUSED           => 0x00000007,
);

my $remote = '\\\\MYREMOTE';

my @services = qw(Fax ClipSrv AcrSch2Svc);

foreach my $svc (@services) {
    my %status;
    my $ret = Win32::Service::GetStatus($remote, $svc, \%status);

    if ($ret) {
        printf(
            "success\t%s\t%s\n",
            $status_codes{ $status{CurrentState} },
            $svc
        );
    }
    else
    {
        warn sprintf(
            "failed to get '%s' status: %s\n",
            $svc,
            Win32::FormatMessage(Win32::GetLastError())
        );
    }
}

For reference, the SERVICE_STATUS structure is documented here.