Question

I have created a stored procedure in which I have used a table object and inserted some column in it. Below is the procedure:

CREATE Procedure [dbo].[usp_Security] (@CredentialsList dbo.Type_UserCredentialsList ReadOnly) As        
Begin        
  Declare        
    @Result Table        
(  

   IdentityColumn Int NOT NULL Identity (1, 1) PRIMARY KEY,    
   UserCredentials  nVarChar(4000),        
   UserName         nVarChar(100),        
   UserRole         nVarChar(200),
   RoleID           Int,    
   Supervisor       Char(3),        
   AcctMaintDecn    Char(3),        
   EditPendInfo     Char(3),        
   ReqInstID        Char(3)
)

Insert Into @Result     
 Select Distinct UserCredentials, 'No', D.RoleName, D.RoleID,'No', 'No', 'No' From @CredentialsList A    
 Join SecurityRepository.dbo.SecurityUsers B On CharIndex(B.DomainAccount, A.UserCredentials) > 0        
 Join SecurityRepository.dbo.SecurityUserRoles C On C.UserID = B.UserID        
 Join SecurityRepository.dbo.SecurityRoles D On D.RoleID = C.RoleID      
 Where D.RoleName Like 'AOT.%' And B.IsActive = 1 And D.IsActive = 1  

Update A        
 Set A.UserName = B.UserName      
 From @Result A        
 Join @CredentialsList B On A.UserCredentials = B.UserCredentials      

-- "Supervisor" Column        
Update A        
Set A.Supervisor = 'Yes'        
From @Result A        
Join SecurityRepository.dbo.SecurityUsers B On CharIndex(B.DomainAccount, A.UserCredentials) > 0        
Join SecurityRepository.dbo.SecurityUserRoles C On C.UserID = B.UserID        
Join SecurityRepository.dbo.SecurityRoles D On D.RoleID = C.RoleID        
Where D.RoleName In ('AOT.Manager', 'AOT.Deps Ops Admin', 'AOT.Fraud Manager', 'AOT.Fulfillment Manager') 
     And B.IsActive = 1 And D.IsActive = 1

-- Return Result        
Select * From @Result Order By UserName, UserRole    
End

In the above procedure, I have made the use of Table object and then created a clustered index on that table object.

However, if I create a temporary table and then process the above info in the SP, will it be faster than using table object instead of temporary table. I tried creating a seperate Clustered index on a column in a table object, but it does not allow me to create it as we cannot create an index on a table object.

I wanted to make use of temporary table in the above stored procedure, but will it reduce the cost as compared to the use of table object.

Answer 1

It depends! – as always there are a lot of factors that come into play here.

A table variable tends to work best for small numbers of rows – e.g. 10, 20 rows – since it never has statistics, cannot have indices on it, and the SQL Server query optimizer will always assume it has just a single row of data. If you have too many rows in a table variable, this will badly skew the execution plan being determined.

Furthermore, the table variable doesn’t participate in transaction handling, which can be a good or a bad thing – so if you insert 10 rows into a table variable inside a transaction and then roll back that transaction – those rows are still in your table variable. Just be aware of that!

The temporary table works best if you intend to have rather many rows, if you might even need to index something.

Temporary tables also behave just like regular tables in transactional processing, e.g. a transaction will affect those temporary tables.

But again: the real way to find out is to try it and measure it – and try again and measure again.