Question

I have decalred

type  TProcedure = procedure(const messageText : String) of object;

and later have a variable of that type decodeProcedure : TProcedure; which gets assigned in various places.

When I am stopped on a breakpint, how can I see which procedure the variablle is pointing to?

If I Debug/evaluate or add watch I get an error E2035 Not enough actual parameters

(Delphi XE 2)

Answer 1

You can evaluate the address of the decodeProcedure method using the @ operator and adding that expression to the watch list windows, to see to which procedure points you can use the local variables window.

try this code

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

type
  TProcedure = procedure(const messageText : String) of object;
  TFooClass = class
     decodeProcedure  : TProcedure;
   public
     procedure Bar(const messageText : String);
     procedure DoIt;
  end;

Var
  F : TFooClass;
{ TFooClass }

procedure TFooClass.Bar(const messageText: String);
begin
  Writeln(messageText);
end;

procedure TFooClass.DoIt;
begin
  if Assigned(decodeProcedure) then //put a break point here
   decodeProcedure('Hello');
end;

begin
  try
     F:=TFooClass.Create;
     try
       F.decodeProcedure:=F.Bar;
       F.DoIt;
     finally
      F.Free;
     end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

And this a sample IDE screenshoot

As you see the local variables window shows which the decodeprocedure points to the TFooClass.Bar method.

UPDATE
You can also add the Self expression to the watch list to get the same results