Question

I have defined a Control with:

 static member ItemsProperty : DependencyProperty = 
        DependencyProperty.Register(
            "Items",
            typeof<MyMenuItemCollection>,
            typeof<MyMenu>,
            null);

 member this.Items
        with get () : MyMenuItemCollection = this.GetValue(MyMenu.ItemsProperty) :?> MyMenuItemCollection
        and set (value: MyMenuItemCollection) = this.SetValue(MyMenu.ItemsProperty, value);

The problem occurs on access:

for menuItem in this.Items do
    let contentElement: FrameworkElement = menuItem.Content

where I get a null reference exception on this.Items;

‘Items’ threw an exception of type
‘System.NullReferenceException’

Immediately after I initialized in the constructor:

do
    this.Items <- new CoolMenuItemCollection()

Answer 1

I think the problem is that static member in F# doesn’t correspond to public field as you may have expected, but to a property with get member. This means, that each time you acccess this.ItemsProperty, you’re actually creating a new dependency property.

You can create a static field like this:

type Control = 
  // private static field
  static let itemsProperty : DependencyProperty =  
    DependencyProperty.Register
      ("Items", typeof<MyMenuItemCollection>, typeof<MyMenu>, null); 
  // public static property with getter 
  static member ItemsProperty = itemsProperty  

  // You can use both private 'itemsProperty' field or public property here
  member this.Items 
    with get () : MyMenuItemCollection = 
      this.GetValue(itemsProperty) :?> MyMenuItemCollection 
    and set (value: MyMenuItemCollection) = 
      this.SetValue(itemsProperty, value)