Question

I have following line in my perl script (which I run from cshell)

system("perl -p -i -e 's/\+[a-z]+\+//g' $file1");

I expect it to delete all the words which are surrounded by + plus signs. Instead, I’m getting below error message.

Quantifier follows nothing in regex; marked by <– HERE in m/+ <– HERE [a-z]++/ at -e line 1.

What is happening? I gave backslashes, why then this error?

Answer 1

Let’s say $file1 contains -foo bar.txt, the string literal

"perl -p -i -e 's/\+[a-z]+\+//g' $file1"

produces the string

perl -p -i -e 's/+[a-z]++//g' -foo bar.txt
                 ^      ^     ^   ^
                 |      |     |   |
                 +---- errors ----+

Don’t create a shell command when you don’t need to. Just launch perl directly.

system("perl", "-p", "-i", "-e", 's/\+[a-z]+\+//g', '--', $file1)

But why create a new process at all? You can use the following to do the exact same thing!

{
    local @ARGV = $file1;
    local $^I = '';
    while (<>) {
        s/\+[a-z]+\+//g;
        print;
    }
}

Or as a sub:

sub fixer {
    my $pat = shift;
    local @ARGV = @_;
    local $^I = '';
    while (<>) {
        s/$pat//g;
        print;
    }
}