Question

I have just solved problem23 in Project Euler, in which I need a set to store all abundant numbers. F# has a immutable set, I can use Set.empty.Add(i) to create a new set containing number i. But I don’t know how to use immutable set to do more complicated things.

For example, in the following code, I need to see if a number ‘x’ could be written as the sum of two numbers in a set. I resort to a sorted array and array’s binary search algorithm to get the job done.

Please also comment on my style of the following program. Thanks!

let problem23 = 
    let factorSum x =
        let mutable sum = 0
        for i=1 to x/2 do
            if x%i=0 then
                sum <- sum + i
        sum
    let isAbundant x = x < (factorSum x)
    let abuns = {1..28123} |> Seq.filter isAbundant |> Seq.toArray
    let inAbuns x = Array.BinarySearch(abuns, x) >= 0
    let sumable x = 
        abuns |> Seq.exists (fun a -> inAbuns (x-a))
    {1..28123} |> Seq.filter (fun x -> not (sumable x)) |> Seq.sum

the updated version:

let problem23b =
    let factorSum x =
        {1..x/2} |> Seq.filter (fun i->x%i=0) |> Seq.sum
    let isAbundant x = x < (factorSum x)
    let abuns = Set( {1..28123} |> Seq.filter isAbundant )
    let inAbuns x = Set.contains x abuns  
    let sumable x = 
        abuns |> Seq.exists (fun a -> inAbuns (x-a))
    {1..28123} |> Seq.filter (fun x -> not (sumable x)) |> Seq.sum

This version runs in about 27 seconds, while the first 23 seconds(I’ve run several times). So an immutable red-black tree actually does not have much speed down compared to a sorted array with binary search. The total number of elements in the set/array is 6965.

Answer 1

You can easily create a Set from a given sequence of values.

let abuns = Set (seq {1..28123} |> Seq.filter isAbundant)

inAbuns would therefore be rewritten to

let inAbuns x = abuns |> Set.mem x

Seq.exists would be changed to Set.exists

But the array implementation is fine too …

Note that there is no need to use mutable values in factorSum, apart from the fact that it’s incorrect since you compute the number of divisors instead of their sum:

let factorSum x = seq { 1..x/2 } |> Seq.filter (fun i -> x % i = 0) |> Seq.sum