Question

I have markup which I would like to remove/transform certain tags from, but retain the data.

For example this:

<div>This is some <b>bold</b> text inside of a div</div>
<p>This is <u>another <b>formatted</b></u> string...<br /></p>

should become this:

<p>This is some <b>bold</b> text inside of a div</p>
<p>This is another <b>formatted</b> string...</p>

Using apply-templates to match each condition doesn’t work due to nesting.

How would you go about doing this?

Answer 1

Sounds like a job for a modified identity transform, like this:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>

    <!--This is the identity template -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>

    <!--This template turns all <div> into <p>-->
    <xsl:template match="div">
        <p>
            <xsl:apply-templates select="@*|node()"/>
        </p>
    </xsl:template>

    <!--This template removes all <u> and continues processing -->
    <xsl:template match="u">
        <xsl:apply-templates select="@*|node()"/>
    </xsl:template>

</xsl:stylesheet>