Question

I have one folder that contains more number of xml files and extract some specific information form xml files. I used libxml to extract wanted information one xml and I succeded but now how can I extract from folder and each xml file using perl script. I tried like this for one xml file:

use warnings;
use strict;
use XML::LibXML::Reader;

my $file;
open( $file, 'formal.xml');
my $reader = XML::LibXML::Reader->new( IO => $file ) 
    or die ("unable to open file");
my %hash;
while ($reader->nextElement( 'nuber' ) ) {
    my $Number = $reader->readInnerXml();
    $reader->nextElement( 'data' ); 
    my $information = $reader->readOuterXml(); 
    $nums{$Number}= $information;
    print( "  NUMBER:$Number\n" );
    print( " Information:$information\n" );
}
print my $num=keys%hash;
close($file);

Above code working properly and extracted what I want. Now I need script that will search all files in the folder and extract the same information from all files.

Answer 1

use File::Find.

Your code cannot be working properly as it is. Here is an untested script that might do what you want.

use warnings; use strict;

use Carp;
use File::Find;
use File::Spec::Functions qw( canonpath );
use XML::LibXML::Reader;

die "Need directories\n" unless @ARGV;

my %hash;
find(
    sub {
        my $file = $_;
        my $path = canonpath $File::Find::name;

        return unless -f $path;
        return unless $file =~ /[.]xml\z/i;

        extract_information($path, \%hash);
        return;
    },
    @ARGV
);

use Data::Dumper;
print Dumper \%hash;

sub extract_information {
    my ($path, $hash) = @_;

    my $ret = open my $xmlin, '<', $path;
    unless ($ret) {
        carp "Cannot open '$path': $!";
        return;
    }

    my $reader = XML::LibXML::Reader->new(IO => $xmlin);
    unless ($reader) {
        carp "Cannot create reader using '$path'";
        return;
    }

    while ($reader->nextElement('number')) {
        my $Number = $reader->readInnerXml();

        $reader->nextElement( 'data' );
        my $information = $reader->readOuterXml();

        $hash->{$path}{$Number} = $information;
    }

    close $xmlin
        or carp "Cannot close '$path': $!";

    return;
}