Question

I have one fundamental doubt in Delphi. When I keep any component at design time, say for example TADOConnectuion and on button click even I write following code then I do not get any error:

begin
  ADOConnection.Free;  //No error
  ADOConnection.Free;  //No error
  ADOConnection.Free;  //No error
end;

But if I create the same object at run time as follwos I get “Access Violation…” error

begin
  ADOConnection := TADOConnection.create(self);
  ADOConnection.Free;  //No error
  ADOConnection.Free;  //Getting an "Access Violation..." error
end;

I get the same error even though I create the object as below:

ADOConnection := TADOConnection.create(nil);

Just would like to know the reason behind such behaviour, i.e. why there is no error when I keep the component at design time ?

Answer 1

If you free a component, its corresponding field in the owner is cleared. If you add a design-time ADOConnection, then

ADOConnection.Free; // Frees ADOConnection and sets ADOConnection to nil
ADOConnection.Free; // Does nothing since ADOConnection is nil

You can see this by capturing it in a variable:

var c: TADOConnection;
c := ADOConnection;
c.Free; // Frees ADOConnection and sets ADOConnection to nil
c.Free; // Error: c is not set to nil

That won’t work, even when ADOConnection is created at design time.

Here’s an example with a TButton component that demonstrates how the behaviour you see for design-time components isn’t specific to design-time components:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  published
    Button: TButton;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  Assert(not Assigned(Button));
  TButton.Create(Self).Name := 'Button'; // Button field gets set
  Assert(Assigned(Button));
  Button.Free;                           // Button field gets cleared
  Assert(not Assigned(Button));
  Button.Free;                           // Okay, Free may be called on nil values
end;

end.