Home/ Questions/Q 8649373
In Process

The Archive Base Latest Questions

Editorial Team
  • 0
Asked: 2026-06-12T13:32:46+00:00

I have problem with parsing XML file using XLTS. <html xmlns=http://www.w3.org/1999/xhtml xml:lang=pl> <body style=margin-top:

  • 0

I have problem with parsing XML file using XLTS.

    <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="pl">
    <body style="margin-top: 0px;">
    <a name="top"/>
    <a name="menu"> </a>
    <a href="cool html"> </a>
    <table width="100%" cellspacing="0" cellpadding="2" border="0" class="aws_border sortable"/>
    </body>
    </html>

And I need to delete all node with <a name="something"> </a>, while preserving <a href> nodes and other nodes in document.

I have tried 

    <xsl:stylesheet version = '1.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>
    <xsl:template match="body"> 
    <xsl:for-each select="a"> 
      <xsl:if test="@href != '' ">
     <xsl:copy-of select="."/> 
    </xsl:if>
         </xsl:for-each> 
    </xsl:template>
    </xsl:stylesheet>

But it preserves only <a href > nodes, and deleting all the other nodes.

Share

Leave an answer

You must login to add an answer.

Need An Account,

1 Answer

  1. Editorial Team

    Preserving all nodes and changing only a few always goes like this:

    1. You use the identity template. It copies (“preserves”) all nodes that are not handled otherwise.
    2. You write another template for each node that should be handled differently.
    3. You resist the urge to use <xsl:for-each>. You don’t need it.

    XSLT:

    <xsl:stylesheet version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xhtml="http://www.w3.org/1999/xhtml"
>

  <!-- the identity template -->    
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()" />
    </xsl:copy>
  </xsl:template>

  <!-- empty template to remove <a name="..."> specifically -->    
  <xsl:template match="xhtml:a[@name]" />

</xsl:stylesheet>

    That’s it.

    Point 3 is actually pretty important. Avoid <xsl:for-each> in all XSLT you write. It seems familiar and helpful, but it’s not. Its use tends to result in clunky, monolithic, deeply nested XSLT code that is hard to re-use.

    Always try to prefer <xsl:template> and <xsl:apply-templates> over <xsl:for-each>.

    • 0