Question

I have some code for starting a process (notepad), and dynamically makes a event handler for the Exited event.

Private WithEvents notepad As New Process

notepad.StartInfo.FileName = "notepad.exe"
notepad.StartInfo.Arguments = fil
notepad.EnableRaisingEvents = True

notepad.Start()
AddHandler notepad.Exited, AddressOf ExitNotepad

But when I try to change the text of a label in the Event handler the application just closes, without any error messages at all.

Sub ExitNotepad(ByVal sender As System.Object, ByVal e As System.EventArgs)

    lblLabel.Text = "Test"

End Sub

Anyone got any ideas?

Answer 1

You need to make it thread-safe, as the event handler may happen in a different thread. Also, I added the handler before starting the process. I used a Button to initiate starting notepad, and my label is named Label1:

Public Class Form1

    Private WithEvents notepad As New Process
    Delegate Sub SetLabel1Callback()

    Sub SetLabel1()
        If Label1.InvokeRequired Then
            Dim d As New SetLabel1Callback(AddressOf SetLabel1)
            Me.Invoke(d)
        End If

        Label1.Text = "Test"
    End Sub

    Sub ExitNotepad(ByVal sender As System.Object, ByVal e As System.EventArgs)
        SetLabel1()
    End Sub

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load

    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim fil = "C:\temp\test.txt"

        notepad.StartInfo.FileName = IO.Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.Windows), "notepad.exe")
        notepad.StartInfo.Arguments = fil
        notepad.EnableRaisingEvents = True
        AddHandler notepad.Exited, AddressOf ExitNotepad

        notepad.Start()
    End Sub
End Class

And I gave it an explicit path to notepad.exe – always use explicit paths where possible.

Tested as working on Windows 7 x64 using the Visual Studio 11 Beta.