Question

I have some shell script as below,

I want to run this process for only 1 minute.

So I want to check the process time and kill the process if it runs > 1 minute. Can anyone help me please?

var=`ps -eaf | pgrep -f getShippingPriceUK.php | wc -l`
if [ $var -lt "1" ]; then
echo "Prozess läuft nicht"
wget -q --timeout=0 --delete-after http://xxxx/001_yakodo/getShippingPrice12.php > /dev/null 2&>1 &
else
echo "Prozess läuft"
fi

Answer 1

If you have perl installed, you can use this perl script.

Save it as timeout, store it in one of the directories in $PATH, make it executable, then replace all calls to

your-script arg1...

with

timeout 1m your-script arg1...

---

#!/usr/bin/perl

use warnings;
use strict;


$SIG{CHLD} = sub { wait; exit };

my $timeout = shift;
for ($timeout) {
    if (defined and /^(\d+)([smh])$/) {
    $_ = $1 * ("s" eq $2 ? 1 : "m" eq $2 ? 60 : 3600);
    } elsif (!defined or /\D/) {
    die "First argument must be time to wait.\n";
    }
}

my @command = @ARGV or die "Must give a command to run.\n";

my $child = fork;
for ($child) {
    die "$0: Cannot fork: $!\n" unless defined;
    last if $child;
    exec {$command[0]} @command or die "$0: Cannot exec: $!\n";
}

close STDIN;
close STDOUT;
close STDERR;
sleep $timeout;
kill TERM => $child;
sleep 5;
kill KILL => $child;