Question

I have the below raw data

1,,35,000  
2,100,45,000

and need the below in a dataset

1 .   35000  
2 100 45000

this would require both dsd option and using comma. informat.

How to carry this out?

Answer 1

DSD has nothing to do with this – DSD involves input like
1,,”35,000″
2,100,”45,000″

If that is what you have, then you can use the : operator to read it in with the comma informat.

data test;
infile datalines dlm=',' dsd;
input id
num
dollar :comma8.;    
datalines;
1,,"35,000"
2,100,"45,000"
;;;;
run;

If you do not have the quotes around the field, then you will need to parse this somehow. One solution is below, which will work as long as the field with commas is the final field.

data test;
infile datalines dlm=',' dsd;
input @;
if countc(_infile_,',') =3 then do;
 _commapos = findc(_infile_,',',-1*length(_infile_));
 _infile_ = substr(_infile_,1,_commapos-1)||substr(_infile_,_commapos+1);
end;
input id
num
dollar ;
put _all_;
datalines;
1,,35,000
2,100,45,000
;;;;
run;

If the field your potential is in is in a consistent field, but NOT the first one, you can modify the above solution to correct it. If it’s in potentially more than one field, you have a much more difficult problem to solve.