Question

I have the following data

Name Date      Number_of_apples
-------------------------------
abc  1-1-2012  5
abc  2-1-2012  3
xyz  1-1-2012  4
xyz  2-1-2012  2
xyz  3-1-2012  6

I want to plot a 2D line graph in excel representing the above data.

Graph should contain Date in X axis and Number of apples in Y axis.

Example plot for name abc :

Depending on selection of name, the graph should update to represent data for that name.

Answer 1

This worked for me. Some notes:

1. This code needs to be placed in a Worksheet module
2. To update the chart simply click the name in your name column e.g. ‘xyz’, ‘abc’ etc.
3. If no chart is present it creates one first and then subseqently updates that same chart

Here’s the code:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not Intersect(Target, Range("A:A")) Is Nothing Then
        UpdateChart Target
    End If
End Sub

Sub UpdateChart(name As Range)
    Dim startRow As Integer, lastRow As Integer
    Dim namerng As Range, data As Range, applechart As ChartObject

    Set namerng = Range("A1:A" & Range("A1").End(xlDown).Row)

    startRow = WorksheetFunction.Match(name.Value, namerng, 0)
    lastRow = startRow + WorksheetFunction.CountIf(namerng, name.Value) - 1

    On Error Resume Next
    Set applechart = ActiveSheet.ChartObjects("AppleChart")
    Set data = Range("B" & startRow & ":C" & lastRow)

    If Not applechart Is Nothing Then
        applechart.Activate
        ActiveChart.SetSourceData Source:=data
    Else
        ActiveSheet.Shapes.AddChart.Select
        ActiveSheet.ChartObjects(1).name = "AppleChart"
        ActiveChart.ChartType = xlLine
        ActiveChart.SetSourceData Source:=data
    End If
End Sub

Edit: How to set-up in Excel

1. In Excel press ALT + F11. This opens the VBA editor
2. In the left hand project window click the worksheet where your data is held e.g. Sheet1
3. In the left hand dropdown select Worksheet
4. In the right hand dropdown select SelectionChange
5. Cut and paste the code

Note – I am assuming your data starts in column A. If not you’ll need to amend the column references in the code yourself