Question

I have the following few lines in a batch file:

@echo off 
echo Running dump...
"D:\wamp\bin\mysql\mysql5.5.16\bin\mysqldump" --host="localhost" --user="****" --password="****" database> "D:\wamp\backup\mysql\"back.%date:~0,2%.sql
echo Done!

Supposedly, it should create a backup file with today’s day as 01, 02, 03, …, 31, that is,

back.01.sql
back.02.sql
back.03.sql

When I run it from CMD, it actually creates it as expected, but when it is run from the scheduler it looks like:

back.Mo.sql
back.Tu.sql
back.We.sql

What date format should I use to ensure it actually created with number of the day of the month?

Answer 1

Working with dates and times in Windows batch is a pain.

The most robust solution is to use WMIC to get the local date and time. It returns a value in the following format:

YYYYMMDDhhmmss.dddddd-ttt

YYYY   = year
MM     = month
DD     = day
hh     = hour in 24 hour format
mm     = minutes
ss     = seconds
dddddd = fractional seconds
ttt    = time zone (minutes difference from Greenwich Mean Time)

So you can use the following to get the current day of the month in a variable
Edit – corrected starting substring location from 7 to 6

set curDate=
for /f "skip=1" %%x in ('wmic os get localdatetime') do if not defined curDate set curDate=%%x
set day=%curDate:~6,2%

The big advantage of this technique is it will work on any Windows machine in the world, regardless of the locale settings.

---

Here is your code with the technique inserted
Edit – corrected starting substring location from 7 to 6

@echo off
echo Running dump...
set curDate=
for /f "skip=1" %%x in ('wmic os get localdatetime') do if not defined curDate set curDate=%%x
set "day=%curDate:~6,2%"
"D:\wamp\bin\mysql\mysql5.5.16\bin\mysqldump" --host="localhost" --user="****" --password="****" database> "D:\wamp\backup\mysql\back.%day%.sql"
echo Done!