Question

I have the following LINQ query which will group by a column and add each group to a datatable in a dataset:

Dim ds As New DataSet
Dim query = From r In bookedorders Group By key = r.Field(Of Integer)("productgroup") Into Group
For Each grp In query
    Dim x As New DataTable
    x = grp.Group.CopyToDataTable()
    ds.Tables.Add(x)
Next

How can I select specific columns from table bookedorders in this query before adding them to the DataTable?
I have 18 columns and I just want to show 4 in the resulted DataTable.

Answer 1

You can only create a DataTable via CopyToDataTable with an IEnumerable(Of DataRow). If you would select only few columns via an anonymous type, you couldn’t create a DataTable from it anymore.

So you need to create another DataTable first with the columns you want to select.

For example:

Dim table2 = New DataTable()
table2.Columns.Add("Column1")
table2.Columns.Add("Column2")
Dim query = From r In bookedorders 
            Group By key = r.Field(Of Integer)("productgroup") Into Group

Dim ds As New DataSet
For Each grp In query
    Dim tbl = table2.Clone()
    ds.Tables.Add(tbl)
    For Each row As DataRow In grp.Group
        Dim newRow = tbl.Rows.Add()
        newRow.SetField("Column1", row.Field(Of String)("Column1"))
        newRow.SetField("Column2", row.Field(Of String)("Column2"))
    Next
Next