Question

I have the following SQL script:

USE MyDatabase

ALTER DATABASE MyDatabase SET SINGLE_USER WITH ROLLBACK IMMEDIATE
GO

BEGIN TRANSACTION

-- Write to tables here

COMMIT TRANSACTION

ALTER DATABASE MyDatabase SET MULTI_USER
GO

I want to make sure that my database is not accessed while the script is running, which is why I am setting the database to SINGLE_USER at the top.

Now, if anything inside the transaction fails (e.g. syntax error) I will never reset the database back to MULTI_USER which means it will be stuck in single user mode permanently (not what I want).

Is there a way to ensure we always go back to MULTI_USER, even on failure?

I guess I’m looking for the equivalent of a finally block in SQL, but from what I have read this doesn’t exist. Is there another way?

It’s worth noting that I cannot move the ALTER DATABASE commands into the transaction, as this is not permitted (since they are committed immediately).

Answer 1

You should be able to use a TRY CATCH to make sure you always go back to MULTI_USER.

You will just need to move the command to switch back to MULTI_USER right after the TRY CATCH block, since FINALLY is not supported in SQL Server.

I ran a quick test with the following SQL and it worked as expected in SQL Server 2005. Just make sure you ROLLBACK the transaction in the CATCH block. I used SELECT 1/0 to force the code into the CATCH block. For debugging purposes, I added the SELECT user_access_desc ... statements to show that the database was indeed switching from single user back to multi user mode.

USE MyDatabase

ALTER DATABASE MyDatabase SET SINGLE_USER WITH ROLLBACK IMMEDIATE
GO

SELECT user_access_desc from sys.databases WHERE Name = 'MyDatabase'

DECLARE @errNum AS INT
DECLARE @errMsg AS VARCHAR(MAX)
SET @errNum = 0

BEGIN TRY

    BEGIN TRANSACTION
    SELECT 1/0
    COMMIT TRANSACTION

END TRY
BEGIN CATCH

    SELECT @errNum = ERROR_NUMBER(), @errMsg = ERROR_MESSAGE()
    ROLLBACK TRANSACTION

END CATCH

IF @errNum <> 0
    SELECT 'An error occurred: ' + CAST(@errNum AS VARCHAR) + '- ' + @errMsg

ALTER DATABASE MyDatabase SET MULTI_USER
GO

SELECT user_access_desc from sys.databases WHERE Name = 'MyDatabase'

EDIT
In my original answer, I had the ALTER ... MULTI_USER statement inside both the TRY and the CATCH block, but that was unnecessary so I moved the statement to right after the TRY CATCH block. I also added some error reporting. Some things to watch out for with this approach are:

1. If you do any error handling or reporting, you’ll need to make sure that SQL doesn’t error. I would probably write the @errNum and @errMsg values to a table (wrapped in a TRY CATCH), switch back to MULTI_USER mode, and then perform whatever other error handling measures that are required, as the local variables will go out of scope after the GO statement.
2. Some errors are unaffected by TRY CATCH. The documentation I linked to above does list out what those conditions are.