Question

I have the following string

Brad Thorm signs for the <hash>All Blacks</hash>

It may not be “All Blacks” between the tags, It could be anything. I need to parse this string such that when the <hash></hash> tags are encountered:

1. Remove all spaces from the string between the tags, i.e. “All Blacks” should become “AllBlacks”
2. Add a “#” symbol to the front of the string between the tags, i.e. “AllBlacks” becomes “#AllBlacks”

Looking for the cleanest way to do this.

Answer 1

Reworking Chris’ code into a function and looping the array, this works for multiple hash instances within the provided string:

<cffunction name="renderHash" output="false" returnType="string">
    <cfargument name="text" required="true" type="string" hint="The text to render." />
        <cfset var strText      = arguments.text />
        <cfset var strHash      = '' />
        <cfset var arrMatches   = reMatch("<hash>(.*?)</hash>", arguments.text) />
            <cfloop array="#arrMatches#" index="i">
                <cfset strHash = reReplace(i, "<hash>(.*?)</hash>", "\1") />
                <cfset strHash = reReplace(strHash, "[[:space:]]", "", "ALL") />    
                <cfset strHash = "##" & strHash />
                <cfset strText = replace(strText, i, strHash) />
            </cfloop>
    <cfreturn strText />
</cffunction>

Pass the string to convert into the function and you’re done:

<cfset strText = '<hash>Brad Thorm</hash> signs for the <hash>All Blacks</hash>' />
<cfset strConverted = renderHash(strText) />