Question

I have the following xml result from this link – https://api.eveonline.com/eve/CharacterID.xml.aspx?names=BorisKarlov

<eveapi version="2">
<currentTime>2013-01-16 18:57:38</currentTime>
<result>
<rowset name="characters" key="characterID" columns="name,characterID">
<row name="BorisKarlov" characterID="315363291"/>
</rowset>
</result>
<cachedUntil>2013-02-16 18:57:38</cachedUntil>
</eveapi>

and I am trying to extract the characterID into asp. I am using the following code,

Set oXML = Server.CreateObject("Msxml2.DOMDocument.6.0")
oXML.LoadXML("https://api.eveonline.com/eve/CharacterID.xml.aspx?names=BorisKarlov")

Set oRoot = oXML.selectSingleNode("//result")

For Each oNode In oRoot.childNodes
  response.Write oNode.Attributes.getNamedItem("characterID").Text
Next 

Set oXML = Nothing 

All i keep getting is the following error:

Microsoft VBScript runtime error ‘800a01a8’

Object required: ‘oRoot’

………….

I can only assume that Set oRoot = oXML.selectSingleNode(“//result”) is not actually generating any data and therefore throwing up the error in the next line.

Can anyone please shed some light on my problem?

Answer 1

You have a few problems there.

1. loadXML() is for loading a block of XML as a string, not fetching from a remote server; for that, you need to use load()
2. when loading from a server, you need to tell it to use the ServerXMLHTTP component, and set async to false so that it waits until loaded before executing the rest of your script.
3. when I tried loading that XML, I got an encoding error; you will need to resolve that one way or another
4. when I loaded the XML directly from a string, it wouldn’t parse because there is a script element containing non-XML content; that needs to be contained within a CDATA section
5. your XPath query is to //result, but you actually need it to be //result/rowset

This code should work once you resolve issues 3 and 4 above:

Set oXML = Server.CreateObject("Msxml2.DOMDocument.6.0")
oXML.async = False
oXML.setProperty "ServerHTTPRequest", true

oXML.Load("https://api.eveonline.com/eve/CharacterID.xml.aspx?names=BorisKarlov")

If oXML.parseError.errorCode <> 0 Then
    Response.Write "<p>XML parse error: " & Server.HTMLEncode(oXML.parseError.reason) & "</p>"
Else
    Set oRoot = oXML.selectSingleNode("//result/rowset")

    If oRoot Is Nothing Then
        response.write "Nothing!"
        response.end
    End If

    For Each oNode In oRoot.childNodes
        response.Write oNode.Attributes.getNamedItem("characterID").Text
    Next
End If

Set oXML = Nothing

Edit: to get around the problem #3, and oddly also #4 (don’t know why!), use this snippet to load the XML instead. For some reason, I think the code above isn’t handling the gzip compressed stream correctly, but this code below does.

Set oXML = Server.CreateObject("Msxml2.DOMDocument.6.0")
Set xh = Server.CreateObject("Msxml2.ServerXMLHTTP.6.0")
xh.open "GET", "https://api.eveonline.com/eve/CharacterID.xml.aspx?names=BorisKarlov", False
xh.send
xml = xh.responseText
oXML.LoadXML xml