Question

I have the pattern something like “keyword : Multinode”. Now, I need to search this pattern in all the files in a directory. If we found the pattern in any of the file, a non empty-string should be returned. It may contain file-name or directory name

In shell scripting the following will do the same

KeyMnode=grep -w "keyword : Multinode" ${dirname}/*

I thought of using find(subroutine,directory_path) and inside the sub-routine I want to traverse through the entire directory for all its entries. For every entry I want to put a check whether it is a readable file or not. If the file is readable, I want to search for the required pattern “keyword : Multinode” in the file found. If we hit with a success, the entire find command should result in a non-empty string(preferably only the existing directory Name) otherwise with an empty string. Please let me know if you need any further information.

I want this to be done using perl. Please help me with the solution.

Answer 1

Here are some Perl tools that will be useful in doing what you described:

• File::Find will do a recursive search for files in a directory and its children, running code (the \&wanted callback in the docs) against each one to determine whether it meets your criteria or not
• The -r operator will tell you whether a file is readable (if (-r $file_name)...)
• open will get you access to the file and <$fh> will read its contents so that you can check with a regular expression whether they match your target pattern
• Adding \b to the beginning and end of the pattern will cause it to match only at word boundaries, similar to grep‘s -w switch

If you have more specific issues, please post additional questions with code that demonstrates them, including statements both of what you expected to happen and of how the actual results differed from your expectation and we’ll be happy to help resolve those issues.

Edit: Cleaned up and runnable version of code from comment:

#!/usr/bin/env perl    

use strict;
use warnings;
use 5.010;

use File::Find;

# Get $dirname from first command-line argument
my $dirname = shift @ARGV;

find(\&do_process, $dirname); # quotes around $dirname weren't needed

my ($KeyMnode, $KeyThreads);

sub do_process {
#  chomp($_); - not needed; $_ isn't read from a file, so no newline on it
  if (-r $_) {  # quotes around $_ weren't needed
    # $_ is just the final part of the file name; it may be better for
    # reporting the location of matches to set $file_name to 
    # $File::Find::name instead
    my $file_name = $_;
    open(my $fh, '<', $file_name);  # Use three-arg open!
    while (<$fh>) {
      chomp();
      # Note that, if you store all matches into the same scalar values,
      # you'll end up with only the last value found for each pattern; you
      # may want to push the matches onto arrays instead.
      if (/\bkeyword : Multinode\b/i) { $KeyMnode   = "$file_name:$_"; }
      if (/\bkeyword : Threads\b/i)   { $KeyThreads = "$file_name:$_"; }
    }
  }
}