Question

I have this script

#!/usr/bin/perl

use warnings;
use strict;

use Data::Dumper;

my %acc = ();

&insert_a(\%acc, 11);
&insert_p(\%acc, 111);
print Dumper %acc;

sub insert_a() {

    my $acc_ref = shift;

    $acc_ref->{"$_[0]"} = {
    a => -1,
    b => -1,
    c => [ { }, ],
    }
}

sub insert_p() {

    my $acc_ref = shift;

    my @AoH = (
    {
        d => -1,
        e => -1,
    }
    );

    push $acc_ref->{"$_[0]"}{"c"}, @AoH;
}

where I am trying to insert AoH into c which also is an AoH, but I am getting

Type of arg 1 to push must be array (not hash element) at ./push.pl line 36, near "@AoH;"
Execution of ./push.pl aborted due to compilation errors.

Any ideas how to do that?

Answer 1

The specific problem is that you can only push to an array, so you first need to dereference the array, and then, since it’s in a larger data structure, you want to set its value to a reference.

#!/usr/bin/perl

use warnings;
use strict;

use Data::Dumper;

my %acc = ();

# don't use & to call subs; that overrides prototypes (among other things)
# which you won't need to worry about, because you shouldn't be using
# prototypes here; they're used for something else in Perl.
insert_a(\%acc, 11);
insert_p(\%acc, 111);
# use \%acc to print as a nice-looking hashref, all in one variable
print Dumper \%acc;

# don't use () here - that's a prototype, and they're used for other things.
sub insert_a {

    my $acc_ref = shift;

    $acc_ref->{"$_[0]"} = {
    a => -1,
    b => -1,
    c => [ { }, ],
    }
}

# same here
sub insert_p {

    my $acc_ref = shift;

    my @AoH = (
      {
        d => -1,
        e => -1,
      }
    );

    # You need to dereference the first array, and pass it a reference
    # as the second argument.
    push @{ $acc_ref->{"$_[0]"}{"c"} }, \@AoH;
}

I’m not quite sure that the resulting data structure is what you intended, but now that you have the program working and can see the resulting structure, you can modify it to get what you need.