Home/ Questions/Q 264103
In Process

The Archive Base Latest Questions

Editorial Team
  • 0
Asked: 2026-05-11T22:39:27+00:00

I have this small class called City that simply holds some information about a

  • 0

I have this small class called City that simply holds some information about a city, here it is:

class com.weatherwidget.City {
    var zipCode:String;
    var forecastText:Array = new Array(5);
}

When I have an array of cities and I change one of the forecastText of one city it will change that forecastText for all of the cities.

For example:

import com.weatherwidget.City;

var arr:Array = new Array();
arr.push(new City());
arr.push(new City());

arr[0].forecastText[0] = "Cloudy";
trace(arr[0].forecastText[0]);
trace(arr[1].forecastText[0]);

Will have the following output:

Cloudy
Cloudy

Even though I only changed arr[0].forecastText[0]. I think I must be misunderstanding something about arrays in objects for actionscript 2.

Share

Leave an answer

You must login to add an answer.

Need An Account,

1 Answer

  1. Editorial Team

    well the reason why … hmmm … little complicated to explain …

    alright … ActionScript is prototype-oriented, as is ECMA-script … classes are only a syntactic sugar introduced by actionscript 2 (this has changed yet again in as3, but that’s a different subject) …

    so if this is the original code:

    class com.weatherwidget.City {
    var zipCode:String;
    var forecastText:Array = new Array(5);
}

    then this is, what actually happens:

    //all classes get stuffed into _global, with packages being a property path:
if (_global.com == undefined) _global.com = {};
if (_global.com.weatherwidget == undefined) _global.com.weatherwidget = {};
//and the actual definition:
_global.com.weatherwidget.City = function () {};
_global.com.weatherwidget.City.prototype = { forecastText:new Array(5) }

    the prototype object of City, that serves as prototype for instances of City, has a property called forecastText, which is an Array of length 5 … so when looking up forecastText on an instance of City, it cannot be found directly and will be looked up in the prototype chain … it will be found in the instance’s prototype … thus, all instances share the same Array …

    the difference is, that the second example gets translated to:

    //same thing here:
if (_global.com == undefined) _global.com = {};
if (_global.com.weatherwidget == undefined) _global.com.weatherwidget = {};
//and the actual definition this time:
_global.com.weatherwidget.City = function () { this.forecastText = new Array(5); };
_global.com.weatherwidget.City.prototype = {}

    as you might have noticed, declared members are only a compiletime thing … if nothing is assigned to them, they simply will not exist at runtime …

    well, this explenation requires, that you either know JavaScript or ActionScript 1 a little, but i hope it helps …

    greetz

    back2dos

    • 0