Question

I have this snippet:

$("#select_sourcer").autocomplete(
    minLength: 2
    source: "/admin/users/list_of_sourcers.json"
    focus: (event,ui) -> 
      $('#select_sourcer').val(ui.item.full_name)
      false
    select: (event,ui) -> 
      $("#select_sourcer").val(ui.item.full_name)
      $("#merchant_sourcer_id").val(ui.item.id)
      false
    ).data("autocomplete")._renderItem = (ul, item) ->
      $("<li></li>").data("item.autocomplete", item).append("<a>" + item.full_name_with_status + "</a>").appendTo ul

And sometimes I get this error:

Cannot set property ‘_renderItem’ of undefined

So I am assuming, that when:

$("#select_sourcer").autocomplete(...).data("autocomplete")

Is undefined, we can’t set the attribute. As talked in this thread: Why am I getting this JS error?

But, how would I do that checking of the voted answer in Coffeescript?

Answer 1

You could use the accessor variant of the existential operator:

The accessor variant of the existential operator ?. can be used to soak up null references in a chain of properties. Use it instead of the dot accessor . in cases where the base value may be null or undefined.

So, if you’re running that jQuery and you’re not certain that you have a #select_sourcer in the DOM, then you could just slip a ? into the right place:

$("#select_sourcer").autocomplete(
  ...
  ).data("autocomplete")?._renderItem = (ul, item) ->
    #-------------------^
    ...

That will have more or less the same effect as:

x = $('#select_sourcer').autocomplete(...).data('autocomplete')
if(x)
    x._renderItem = (ul, item) -> ...

The above is just for illustrative purposes, ?. actually checks != null rather than general falsiness.

This should only be necessary if there is no #select_sourcer in the DOM so you might want to avoid attempting to bind the autocompleter altogether if you don’t need it; OTOH, sometimes it is easier to not care if it is there or not and bind away.