Question

I have this Stored Procedure which returns records containing the specified keyword.

CREATE procedure [dbo].[SearchKeywordPaged](
    @KeyWordFilter varchar(50)
    ,@PageNumber int = 1)      

as
begin

declare @PageSize int = 50
declare @FirstRow int
declare @LastRow int
declare @TotalRows int

SELECT      @FirstRow = (@PageNumber - 1) * @PageSize + 1,
            @LastRow = (@PageNumber - 1) * @PageSize + @PageSize;

select @TotalRows =      COUNT(*) from 
    [Quotes] q inner join [Keywords] k 
    ON q.id = k.Quoteid where k.Keyword = @KeyWordFilter;

with Results as
(                  
    SELECT            
        q.*
        ,ROW_NUMBER() over (Order By Author asc) as Instance_Count
        ,@TotalRows as the_Count
    FROM [Quotes] q
    INNER JOIN [Keywords] k ON q.id = k.Quoteid
    WHERE k.Keyword = @KeyWordFilter
)            

select      *
from      results
where      Instance_Count between @FirstRow and @LastRow
order by Instance_Count asc

end

How can I modify this stored procedure to accept more than 1 keyword for search ?

Answer 1

Create a function that convertes a string into a table. You can use the example below:

IF  EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[fn_SplitString]') AND type in (N'FN', N'IF', N'TF', N'FS', N'FT'))
DROP FUNCTION [dbo].[fn_SplitString]
GO
CREATE   FUNCTION [dbo].[fn_SplitString]    (@xStr varchar(8000))
RETURNS @out table (
    x varchar(500))  AS  
begin

declare @lp int set @lp=1
declare @xlen int
set @xlen=len(@xstr)

declare @xchar char(1)
declare @thisSplit varchar(50)
set @thisSplit=''

while @lp <= @xlen
 begin
    set @xchar=substring(@xstr,@lp,1)

    set @thisSplit=@thisSplit + @xchar

        if (@xchar=',') or (@lp=@xlen)
         begin
            insert into @out (x) values (replace(@thisSplit,',',''))
            set @thisSplit=''
         end
    set @lp=@lp+1   
 end


RETURN  
end
GO
select X from fn_SplitString('aaa,bbb,cccc')

Then, modify the WHERE clause of your stored procedure like this:

WHERE k.Keyword in (select x from fn_SplitString(@KeyWordFilter) ) 

Finally, you can use your SP passing a list of keywords as a comma separated list, like this:

exec [SearchKeywordPaged]  @KeyWordFilter='keyword1,keyword2,...'