Question

I have this xml file:

<A>
<B>
    <elt>Add</elt>
    ...there are some element here
    <bId>2</bId>
</B>
<B>
    <elt>Add</elt>
    ...there are some element here
    <bId>2</bId>
</B>
<B>
    <elt>Add</elt>
    ...there are some element here
    <bId>2</bId>
</B>
<B>
    <elt>can</elt>
    ...there are some element here
    <bId>3</bId>
</B>
<B>
    <elt>can</elt>
    ...there are some element here
    <bId>3</bId>
</B>

I want to check the value of each bId element. If this value is the same with the preceding or following bId element, then I will put the other elements of the bloc B in another bloc excepted the element bId which will be rejected after the transformation. To make my question understanding by you, here is the expected output:

<CA>
  <cplx>
    <spRule>
            <elt>Add</elt>
             ...
    </spRule>
    <spRule>
            <elt>Add</elt>
             ...
    </spRule>
    <spRule>
            <elt>Add</elt>
            ...
    </spRule>
  </cplx>
  <cplx>
    <spRule>
            <elt>can</elt>
            ...
    </spRule>
    <spRule>
            <elt>can</elt>
            ...
    </spRule>
  </cplx>
</CA>

Even though when the element in the xml file are not sorted by the value of bId, I want also get the same expected output.
I try to use this xsl code:

<xsl:for-each select="bId"
  <CA>
    <cplx>
    <xsl:choose>
      <xsl:when test="node()[preceding::bId]">
         <xsl:copy>
          <xsl:copy-of select="@*"/>
          <xsl:apply-templates/>
         </xsl:copy>
      </xsl:when>
    </cplx>
  </CA>
</xsl:for-each>

but it doesn’t walk. Could someone help me please?
Thanks

Answer 1

Assuming your first description to group adjacent elements with the same bId value is what you want an XSLT 1.0 way is as follows:

<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:strip-space elements="*"/>
  <xsl:output indent="yes"/>

  <xsl:key name="k1"
    match="B[bId = preceding-sibling::B[1]/bId]"
    use="generate-id(preceding-sibling::B[not(bId = preceding-sibling::B[1]/bId)][1])"/>

  <xsl:template match="A">
    <CA>
      <xsl:apply-templates select="B[not(preceding-sibling::B[1]) or not(bId = preceding-sibling::B[1]/bId)]"/>
    </CA>
  </xsl:template>

  <xsl:template match="B">
    <cplx>
      <xsl:apply-templates select=". | key('k1', generate-id())" mode="sp"/>
    </cplx>
  </xsl:template>

  <xsl:template match="B" mode="sp">
    <spRule>
      <xsl:copy-of select="node()[not(self::bId)]"/>
    </spRule>
  </xsl:template>

</xsl:stylesheet>

If you simply want to group all B elements with the same bId value then use

<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:strip-space elements="*"/>
  <xsl:output indent="yes"/>

  <xsl:key name="k1"
    match="B"
    use="bId"/>

  <xsl:template match="A">
    <CA>
      <xsl:apply-templates select="B[generate-id() = generate-id(key('k1', bId)[1])]"/>
    </CA>
  </xsl:template>

  <xsl:template match="B">
    <cplx>
      <xsl:apply-templates select="key('k1', bId)" mode="sp"/>
    </cplx>
  </xsl:template>

  <xsl:template match="B" mode="sp">
    <spRule>
      <xsl:copy-of select="node()[not(self::bId)]"/>
    </spRule>
  </xsl:template>

</xsl:stylesheet>