Question

I have trouble in assigning an argument value / command line arguments. Here is what i actually want to do.

Test.pl
#!/usr/bin/perl

#Variable declaration

$RUN_DIR="/home/ckhau/database/experiment/test";
    #Main program

$index=-999; 
#my $ARGV;
@files = <$RUN_DIR/b*.txt>;

foreach $file (@files)
{
 #$SCRIPT="perl abcdinfo.pl $file";
 $SCRIPT="perl abc.pl $file";
 system("$SCRIPT");       
}

I tried replacing b*.txt with @ARGV and tried running the program i.e when i replace the above code with

@files = <$RUN_DIR/@ARGV>;

Then try to run with command line

perl Test.pl b*.txt

This gives me an error perl: no match. Can anyone help me on the following.

How to use command line argument for this ???

Can i use these kind of syntax in command lines “b*.txt” or “r_*.txt”???

Answer 1

The shell is trying to expand b*.txt to the list of matching files in your current directory. Once your program receives those values, your glob looks like

@files = </home/ckhau/database/experiment/test/b1.txt b3.txt b3.txt>

which isn;t what you want, and will fail to find any files if there is no b1.txt in your $RUN_DIR directory

To prevent the shell globbing a wildcard file pattern you just need to put it in quotes, so your command becomes

perl Test.pl 'b*.txt'

Beyond that, your program really needs improving. You should always use strict and use warnings at the head of all your programs, and declare every variable at its point of first use; you should really use just the first element of @ARGV as your file pattern, instead of the whole array; and it is wrong to put scalar variables in quotes when you simply want their contents

Take a look at this refactoring of your original

#!/usr/bin/perl

use strict;
use warnings;

my $run_dir="/home/ckhau/database/experiment/test";

my $pattern = "$run_dir/$ARGV[0]";

my $index = -999; 
my @files = glob $pattern;

foreach my $file (@files) {
  my $script = "perl abc.pl '$file'";
  system $script;
}

Update

If you really want to have multiple wildcard patterns as parameters to Test.pl then you must patch the $run_dir directory onto the beginning of each of them. The best way to do this is to employ the File::Spec module’s rel2abs function. The complete script would look like this

#!/usr/bin/perl

use strict;
use warnings;

use File::Spec;

my $run_dir="/home/ckhau/database/experiment/test";

my $pattern = join ' ', map File::Spec->rel2abs($_, $run_dir), @ARGV;

my $index = -999;
my @files = glob $pattern;

foreach my $file (@files) {
  my $script = "perl abc.pl '$file'";
  system $script;
}