Question

I have two node sets where I’d like to output the value(s) of (a) node(s) if there are no matches. The logic would be the following:

If any of the values of the attributes “term” in Node Set #1 do not match any of the values of the “key” attributes in Node Set #2, output the “term” value(s) from Node Set #1. How would I do this?

Node Set #1

    <stuff term="foo" />
    <stuff term="bar" />
    <stuff term="test" />

Node Set #2

    <other key="time" />
    <other key="rack" />
    <other key="foo" />
    <other key="fast" />

Answer 1

Assuming your XML looks like this

<record>
   <stuff>
      <stuff term="foo"/>
      <stuff term="bar"/>
      <stuff term="test"/>
   </stuff>
   <other>
      <other key="time"/>
      <other key="rack"/>
      <other key="foo"/>
      <other key="fast"/>
   </other>
</record>

You could set up a key to look up the other elements based on their key attribute

<xsl:key name="other" match="other/*" use="@key"/>

Then, to select your stuff elements for which there is no matching other element, you would use the key like so

<xsl:apply-templates select="stuff/*[not(key('other', @term))]"/>

Try the following XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:key name="other" match="other/*" use="@key"/>

   <xsl:template match="/*">
      <xsl:apply-templates select="stuff/*[not(key('other', @term))]"/>
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

When applied to the above XML, the following is output

<stuff term="bar"></stuff>
<stuff term="test"></stuff>