Question

i have used the delphi data binding wizard with my xml file, and everything compiles and runs fine.

I have 3 comboboxes on my form. Manufacturer, Model and Year.

Manufacturer is populated using the following code on FormCreate.

procedure TfrmMain.FormCreate(Sender: TObject);
var
  RGearing : IXMLracegearingType;
  i : Integer;
begin
  // Load XML Document into Memory
  RGearing := Getracegearing(XMLDocument1);

  // Populate Manufacturer combobox
  for i := 0 to RGearing.Car.Count-1 do
  begin
    cbManufac.Items.Add(RGearing.Car[i].Manufacturer);
  end;

  // Copy current selected Manufacturer to string variable
  varManufac := cbManufac.ListItems[(cbManufac.ItemIndex)].Text;
end;

My question is how can i populate the Model combobox based on the current manufacturer that is selected.

Here is the XML File that goes with it

<?xml version="1.0" encoding="UTF-8"?>
<gearing>
  <car>
    <id>1</id>
    <manufacturer>Ford</manufacturer>
    <model>Test 1</model>
    <year></year>
  </car>
  <car>
    <id>2</id>
    <manufacturer>Ford</manufacturer>
    <model>Test 2</model>
    <year></year>
  </car>
  <car>
    <id>3</id>
    <manufacturer>Honda</manufacturer>
    <model>Test 1</model>
    <year></year>   
  </car>
  <settings>
    <form_height></form_height>
    <form_width></form_width>
  </settings>
</gearing>

So if the manufacturer selected is Ford then the model combobox needs to display Test 1 and Test 2 as the items.

Answer 1

I can not see your function and the type

RGearing : IXMLracegearingType; 
RGearing :=Getracegearing(XMLDocument1);

So I can only test it with the following code.
Go through the code and customize it to your needs.

unit xmlCombo;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    cbManufac: TComboBox;
    cbModel: TComboBox;
    procedure getManufac;
    procedure getModel(const ManufacVal:string);
    procedure FormActivate(Sender: TObject);
    procedure cbManufacClick(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}
uses MSXML,ActiveX,ComObj;

const
 XMLTestStr =
 '<?xml version="1.0" encoding="UTF-8"?>'+
 '<gearing>'+
 ' <car>'+
 '   <id>1</id>'+
 '   <manufacturer>Ford</manufacturer>'+
 '   <model>Test 1</model>'+
 '   <year></year>'+
 ' </car>'+
 ' <car>'+
 '   <id>2</id>'+
 '   <manufacturer>Ford</manufacturer>'+
 '   <model>Test 2</model>'+
 '   <year></year>'+
 ' </car>'+
 ' <car>'+
 '   <id>3</id>'+
 '   <manufacturer>Honda</manufacturer>'+
 '   <model>Test 1</model>'+
 '   <year></year>'+
 ' </car>'+
 ' <settings>'+
 '   <form_height></form_height>'+
 '   <form_width></form_width>'+
 ' </settings>'+
'</gearing>';

var
  varManufac : string;
  RGearing  : IXMLDOMDocument;

procedure TForm1.cbManufacClick(Sender: TObject);
begin
     getModel(cbManufac.Items[cbManufac.ItemIndex]);
end;

procedure TForm1.FormActivate(Sender: TObject);
begin
  RGearing:=CoDOMDocument.Create;
  RGearing.loadXML(XmlTestStr);
  getManufac;
end;

procedure TForm1.getModel(const ManufacVal:string);
Var
  XMLDOMNodeL  : IXMLDOMNodeList;
  ChildST : String;
  ChildN,BNode : IXMLDOMNode;
  i : Integer;

begin
  cbModel.Items.Clear;
  cbModel.Text:='';
  XMLDOMNodeL:=RGearing.getElementsByTagName('car');
  for i := 0 to XMLDOMNodeL.length-1 do
  begin
    ChildN:=XMLDOMNodeL[i].selectSingleNode('manufacturer');
    if ChildN.text=ManufacVal then begin
       BNode:=XMLDOMNodeL[i].selectSingleNode('model');           
       ChildST:=BNode.text;
       if cbModel.Items.IndexOf(ChildST) = -1 then cbModel.Items.Add(ChildST);
    end;
  end;
end;

procedure TForm1.getManufac;
Var
  XMLDOMNodeList  : IXMLDOMNodeList;
  ChildST : string;
  i : Integer;

begin
  cbManufac.Items.Clear;
  cbManufac.Text:='';
  // Populate Manufacturer combobox
  XMLDOMNodeList:=RGearing.getElementsByTagName('manufacturer');
  for i := 0 to XMLDOMNodeList.length-1 do
  begin
    ChildST:=XMLDOMNodeList[i].text;
    if cbManufac.Items.IndexOf(ChildST) = -1 then cbManufac.Items.Add(ChildST);
    if cbManufac.Items.Count = 1 then begin
       cbManufac.Text:=ChildST;
       getModel(ChildST);
    end;
  end;
end;

end.

To load xml from a file.

if RGearing.Load('File.xml') then
  [...]
 else
  ShowMessage('Could not load file : File.xml');
end;

I hope this helps.