Question

I have very little background in website programming so I apologise if this might be an obvious question.

I am updating some pages on a website using ASP. On a particular page, I have a list of pdf files that people can download. Currently, the title of the file is written in directly onto the page along with a link to it

myPage.asp    
<tr>
<td>Title</td>
<td><a href="something.pdf">PDF</a></td>
</tr>

I wanted to collect all the titles and filenames into one table, for example:

FileCode   Title    Filename
001        ABC      abcfile.pdf
002        XYZ      xyz.pdf

So that when I am populating the page I can use something like the following,

<tr>
<td>Table(code).Title</td>
<td><a href=Table(code).Filename>PDF</a></td>
</tr>

The code doesn’t have to look like that (I don’t know what it will look like); this is just an example to show what I mean: I want to be able to keep all the file information in one location so it is easy to update and add things to it, and I can just reference it when I need to display some information.

The reason I am doing this is because I don’t want the user to be able to directly click the pdf link and get the file; they must go through a contact form to get the file and I thought it might be easier to just send a file code instead of the actual filename,

<a href="contactForm.asp?code=001">PDF</a>

So this table will be accessed by contactForm.asp as well. Hence I wanted a central location for such a table and I didn’t know what are the acceptable conventions for websites.

Answer 1

The simplest solution would be to store the files in an array in an ASP include file, like this:

files.asp

<%
Dim files(2, 2)
files(0, 0) = "1"
files(1, 0) = "File title 1"
files(2, 0) = "file1.txt"
files(0, 1) = "2"
files(1, 1) = "File title 2"
files(2, 1) = "file2.txt"
files(0, 2) = "3"
files(1, 2) = "File title 3"
files(2, 2) = "file3.txt"
%>

(if the files are in a folder you would add the path, eg “/folder/file1.txt”)

To display a list of files you could use this code:

showfiles.asp

<!--#include file="files.asp"-->
<table>
<tr>
<td>FileCode</td>
<td>Title</td>
<td>Filename</td>
</tr>
<% Dim i : For i = 0 To UBound(files, 2) %>
<tr>
<td><%= files(0, i) %></td>
<td><%= files(1, i) %></td>
<td><%= files(2, i) %></td>
</tr>
<% Next %>
</table>

And to send the file to the browser you could use one of the following methods. The first one is just a simple redirect to the file, and the second actually loads the file and writes the file to the browser so that the user does not know the path to the file (more secure but not very secure):

contact.asp

<!--#include file="files.asp"-->
<%
Dim code, file, i
code = Request.QueryString("code")
For i = 0 To UBound(files, 2)
    If files(0, i) = code Then
        file = files(2, i)
        Exit For
    End If
Next
If file <> "" Then
    Response.Redirect(file)
Else
    Response.Write("File not found")
End If
%>

contact2.asp

<!--#include file="files.asp"-->
<%
Dim code, file, i, stream
code = Request.QueryString("code")
For i = 0 To UBound(files, 2)
    If files(0, i) = code Then
        file = files(2, i)
        Exit For
    End If
Next
If file <> "" Then
    Set stream = Server.CreateObject("ADODB.Stream") 
    stream.Open 
    stream.Type = 1
    stream.LoadFromFile(Server.MapPath(file))
    Response.BinaryWrite(stream.Read) 
Else
    Response.Write("File not found")
End If
%>

Hopefully you can use some of this to make what you need?