Question

I have xml like

<programs>
 <program name="breaking laws" id="97;#ttt;#98;#tpl;#41;#fel" />
   <program name="advanced technology" id="89;#hjk;#95;#uio;#81;#lpk" />
 <program name="Emerging companies " id="88;#ple;#98;#tpl;#41;#fel" />
 <program name="breakinglaws" id="97;#ttt" />
 <program name="breakinglaws" id="97;#ttt;#98;#tpl;#81;#lpk" />
 <program name="breakinglaws" id="99;#hklo;#95;#uio" />
</programs>

I would like to find all the unique ids text using xslt 1.0 i.e

ttt
tpl
fel
hjk
uio
lpk
ple
hklo

I was trying to do something using key and output tokens

<xsl:template name="output-tokens">
        <xsl:param name="list" />
        <xsl:variable name="newlist" select="concat(normalize-space($list), ' ')" />
        <xsl:variable name="first" select="substring-before($newlist, ';#')" />
        <xsl:variable name="remaining" select="substring-after($newlist, ';#')" />
        <id>
            <xsl:value-of select="$first" />
        </id>
        <xsl:if test="$remaining">
            <xsl:call-template name="output-tokens">
                <xsl:with-param name="list" select="$remaining" />
            </xsl:call-template>
        </xsl:if>
    </xsl:template>

Answer 1

Here is one solution

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="/programs">
      <!-- Variable containing concateneated list of all program elements**
      <xsl:variable name="allprograms">
         <xsl:apply-templates select="program"/>
      </xsl:variable>

      <!-- Call recursive template to split the list -->
      <xsl:call-template name="output-tokens">
         <xsl:with-param name="list" select="$allprograms" />
      </xsl:call-template>
   </xsl:template>

   <!-- Template used to concatenate all program elements -->
   <xsl:template match="program">
      <xsl:value-of select="concat(@id, ';#') "/>
   </xsl:template>

   <!-- Recursive template to split out list into unique elements -->
   <xsl:template name="output-tokens">
      <!-- List to split -->
      <xsl:param name="list"/>
      <!-- List of all currently processed elements -->
      <xsl:param name="newlist" select="';#'" />

      <!-- Get first variable in list, and also the remaining part of the list -->
      <xsl:variable name="first" select="substring-before($list, ';#')"/>
      <xsl:variable name="remaining" select="substring-after($list, ';#')"/>

      <!-- Check if first variable is not a number, and is not contained in currently processed list -->
      <xsl:if test="number($first) != number($first) and not(contains($newlist, concat(';#', $first, ';#')))">
         <id>
            <xsl:value-of select="$first"/>
         </id>
      </xsl:if>

      <!-- If there are still elements left in the list, call the template recursively -->
      <xsl:if test="$remaining">
         <xsl:call-template name="output-tokens">
            <xsl:with-param name="list" select="$remaining"/>
            <xsl:with-param name="newlist" select="concat($newlist, $first, ';#')"/>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>
</xsl:stylesheet>

The idea is you first build up a single string containing all the program elements concatenated together. You then call a recursive template which gets the first element from the list, and then checks it has not already been processed (this is achieved by the template also containing a variable of already processed elements)

When the XSLT is applied to your sample XML, the following is output:

<id>ttt</id>
<id>tpl</id>
<id>fel</id>
<id>hjk</id>
<id>uio</id>
<id>lpk</id>
<id>ple</id>
<id>hklo</id>