Question

I intend to generate random number the following step:

1. Read the data from file (<DATA>)
2. Generate random numbers as many as the input data lines
3. The random number should not be generated twice,
   e.g. if the rand number generated in loop no x, has been created
   before then, recreate the random number.

Here is the code I have which leads to infinite loop.
What’s wrong with my logic, and how can I fix it?

#!/usr/bin/perl -w
use strict;
my %chrsize = ('chr1' =>249250621);

# For example case I have created the
# repository where a value has been inserted.
my %done =("chr1    182881372" => 1);

while ( <DATA> ) {
 chomp;
 next if (/^\#/);

 my ($chr,$pos) = split(/\s+/,$_);
 # this number has been generated before
 # with this: int(rand($chrsize{$chr}));
 # hence have to create other than this one
 my $newst =182881372;

 my $newpos = $chr ."\t".$newst;


 # recreate random number
 for (0...10){
     if ( $done{$newpos} ) {

            # INFINITE LOOP
            $newst = int(rand($chrsize{$chr}));
            redo;
     }
 }

 $done{$newpos}=1;
print "$newpos\n";

}


__DATA__
# In reality there are 20M of such lines
# name  positions
chr1    157705682
chr1    19492676
chr1    169660680
chr1    226586538
chr1    182881372
chr1    11246753
chr1    69961084
chr1    180227256
chr1    141449512

Answer 1

You had a couple of errors:

1. You were setting $newst within your loop every time, so $newpos never took on a new value.
2. Your inner for loop didn’t make sense, because you never actually changed $newpos before checking the condition again.
3. redo; was working on the inner loop.

Here is a corrected version that avoids redo altogether.

Update: I edited the algorithm a bit to make it simpler.

 #!/usr/bin/perl -w
use strict;
my $chr1size = 249250621;

my %done;
my $newst;

while ( <DATA> ) {
    chomp;
    next if (/^\#/);
    my ($chr,$pos) = split(/\s+/,$_);

    my $newpos;
    #This will always run at least once
    do {
        $newst = int(rand($chr1size));
        $newpos = $chr ."\t".$newst;
    } while ( $done{$newpos} );

    $done{$newpos}=1;
    print "$newpos\n";
}

Update 2: while the above algorithm will work, it will get really slow on 20,000,000 lines. Here is an alternative approach that should be faster (There is sort of a pattern to the random numbers it generates, but it would probably ok for most situations).

#!/usr/bin/perl -w
use strict;
my $newst;

#make sure you have enough.  This is good if you have < 100,000,000 lines.
use List::Util qw/shuffle/;
my @rand_pieces = shuffle (0..10000);

my $pos1   = 0;
my $offset = 1;
while ( <DATA> ) {
    chomp;
    next if (/^\#/);
    my ($chr,$pos) = split(/\s+/,$_);

    $newst = $rand_pieces[$pos1] * 10000 + $rand_pieces[($pos1+$offset)%10000];
    my $newpos = $chr ."\t".$newst;

    $pos1++;
    if ($pos1 > $#rand_pieces) 
    {
        $pos1 = 0;
        $offset = ++$offset % 10000;
        if ($offset == 1) { die "Out of random numbers!"; } 
    }

    print "$newpos\n";
}