Question

I know nothing about Flash Professional, but a friend has given me a .swf that supposedly contains some graphics that he wants imported into a Flex program – which I know a fair bit about.

I have the .swf, but I have no idea what to put for “symbol”. My friend doesn’t seem to know what I’m talking about. How can I determine the symbol name to put in the 2nd parameter of the embed?

[Embed(source='SomeSwf.swf', symbol='WhatGoesHere??')]

Is there some way to browse the .swf, or some way to just import the whole thing and step through the symbols in actionscript?

Thanks In Advance.

Answer 1

You should specify the Linkage name of the symbol as the 2nd parameter.
To set up Linkage name your friend should select symbol from Library panel, open its properties, and select “Export for Actionscript” checkbox, specify class name (if needed):

Class name specified in this panel is the 2nd parameter you should use to embed that object. After publishing swf you’ll be able to instance that symbol object this way:

public class EmbedTest extends Sprite
{
    [Embed (source = "square.swf", symbol="Square")]
    private var swfAsset:Class;

    public function EmbedTest():void    
    {
        var embeddedSwf:*=new swfAsset();
        addChild(DisplayObject(embeddedSwf));
    }
}

UPD1:

Is there some way to browse the .swf,
or some way to just import the whole
thing and step through the symbols in
actionscript?

You may try to step through all on-stage symbols of the embedded swf this way:

package
{
    import flash.display.DisplayObject;
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.utils.getDefinitionByName;

    [SWF(backgroundColor="#FFFFFF", width="1000", height="400")]
    public class EmbedTest extends Sprite
    {
        [Embed (source = "yourSwf.swf")]
        private var swfAsset:Class; 
        public function EmbedTest()
        {
            super();    
            var embeddedClip:Sprite=new swfAsset() as Sprite;
            var loader:Loader=Loader(embeddedClip.getChildAt(0));
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadCompleteFunction);
        }

        private function loadCompleteFunction(e:Event):void {
            var loaderInfo:LoaderInfo=e.target as LoaderInfo;
            var content:MovieClip=loaderInfo.loader.content as MovieClip;
            for (var i:int=0; i<content.numChildren; i++) {
                var embeddedMovieClipChild:*=content.getChildAt(i);
                trace (embeddedMovieClipChild.name, embeddedMovieClipChild);
            }
        }
    }
}

UPD2:
Also consider adding assets to your project as swc files. http://blog.geewa.com/post/2009/03/16/Integrating-Flash-Professional-and-Flex-Builder-Using-SWC.aspx