Question

I know that in xslt not have the break statement and don’t know how to solve my problem.

Example

      <tag name="param" />
      <tag name="Token" />
      <tag name="Token" />
      <tag name="Token" />
      <tag name="param" />
      <tag name="Token" />
      <tag name="param" />
      <tag name="Token" />
      <tag name="Token" />
      <tag name="Token" />
      <tag name="return"/>

Parameter must be grouped with all token before next param. How I can do it?

Output must be something like this:

param
    Token
    Token
    Token
param
    Token
param
    Token
    Token
    Token   

Answer 1

Another way to achieve this would be a key to match the “non-param” elements, grouping them by the first most preceding param-element

<xsl:key 
  name="params" 
  match="tag[@name!='param']" 
  use="generate-id(preceding-sibling::tag[@name='param'][1])" />

Then, you would start by matching your “param” elements

<xsl:apply-templates select="tag[@name='param']" />

And for each one you match, you could then select the associated tags in group by using the key

<xsl:apply-templates select="key('params', generate-id())" />

Try the following XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="text" />
   <xsl:key name="params" match="tag[@name!='param']" use="generate-id(preceding-sibling::tag[@name='param'][1])" />

   <xsl:template match="/*">
      <xsl:apply-templates select="tag[@name='param']" />
   </xsl:template>

   <xsl:template match="tag[@name='param']">
      <xsl:text>param&#10;</xsl:text> 
      <xsl:apply-templates select="key('params', generate-id())" />
   </xsl:template>

   <xsl:template match="tag">
      <xsl:value-of select="concat(' - ', @name, '&#10;')" />
   </xsl:template>
</xsl:stylesheet>

When applied to your sample XML (assuming a root lelement), the following is output

param
 - Token
 - Token
 - Token
param
 - Token
param
 - Token
 - Token
 - Token
 - return

If you don’t want the “return” element you could add another template to match it and then ignore it.