Question

I love Pascal for its clarity, so believe what the following code snippet along with question title is self-explanatory:

procedure TForm1.FormClick(Sender: TObject);
const
  N = 42; { fnord }
type
  { this structure merely defines memory layout }
  TStringStruct = record
    NumberOfCharacters: Cardinal;
    { this array supposed to be friendly for the string type }
    StringCompatibleArray: array [0..N-1] of Char;
  end;
  { actual work is done with pointer to that structure }
  PStringStruct = ^TStringStruct;
var
  StringStruct: PStringStruct;
  S: string;
begin
  StringStruct := PopulatedElsewhere;

  { most pleasant code but will copy no more than N characters }
  S := StringStruct^.StringCompatibleArray;

  { this construct works but is way too ugly and complex }
  SetString(
    S,
    { in particular: must reference the array and then typecast to make it work }
    { default $T- state assumed, unfortunately $T+ has global effect and not useful here }
    PChar(@StringStruct^.StringCompatibleArray),
    StringStruct^.NumberOfCharacters
  );
end;

In case someone wants formal question: i’d like to see which options i have to perform such assignment, preferably less obscure than shown SetString call.

Note: i know what dereference operators are optional with structured types.

Answer 1

SetString is the way to go, ordinarily. It’s only obscure if people continue to remain ignorant about its usefulness. The type casting is necessary because there are two overloads, and the char array doesn’t exactly match either expected argument type (PAnsiChar and PWideChar).

It’s wordy, but in your case it’s easily wrapped into a function for your data type, like ToString. As David suggested in a comment, you can let that function be the Implicit operator, and then you get the conversion automatically:

class operator TStringStruct.Implicit(const Value: TStringStruct): string;
begin
  SetString(Result, Value.StringCompatibleArray, Value.NumberOfCharacters);
end;

S := StringStruct^;