Question

I may be doing something really stupid, but I don’t get why the below code doesn’t work…

Here, I create a generic Object called spellbook:

// A list of all the player's spells
public var spellBook:Object = {};

Here, I add a key-value pair to the spellbook:

spellBook["bubble"] = new BubbleSpell(spellBook);

And here I try to output the contents of the spellbook:

trace("Spells initialised.  Available spells are:");
for each (var _spell:String in spellBook)
{
    trace("  ", _spell, " : ", spellBook[_spell]);
}

But this is the output I get:

Spells initialised.  Available spells are:
   [object BubbleSpell]  :  undefined

What I don’t get is why it’s not outputting:

Spells initialised.  Available spells are:
   bubble : [object BubbleSpell]

??

It’s as if I’m iterating over the values in spellbook, rather than the keys… is that what’s happening? All the docs I’ve seen so far seem to indicate that this is the correct way to iterate over a dictionary (which a generic object kind of is…) Do I need to call a method to get keys instead of values for generic objects?

So confused!

Answer 1

for each is used to iterate over values, you want to use a for loop which iterates over keys, eg:

var mySpells = { 
    speedy: new SpeedySpell(),
    sleepy: new SleepySpell()
};

for (var key : String in mySpells) {
    trace("key: " + key + " value: " + mySpells[key]);
}

Note that when iterating over the keys in a Dictionary you should leave the key value untyped (*) as a Dictionary’s keys can be of any type (whereas an Object‘s keys can only be of type String).

A common trick would be to create a utility function which extracts an Object’s keys to an Array for easier iteration:

function getKeys(source : Object) : Array {
    const result : Array = [];
    for (var key : * in source) {
        result.push(key);
    }
    return result;
}

You can then make use of this helper function:

trace(getKeys(mySpells));