Question

I need all duplicate for a particular value with same column color.This will help me in finding how many duplicates are there for a particular value,corresponding column values etc.
Please find Sample Excel. If I do Conditional formatting, highlight duplicates, this will give same color to all the duplicates irrespective of values.This wont solve the purpose.
Also suggest other way of differentiating in duplicate values in excel if any.

Answer 1

There’s no way to do what you want with conditional formatting, but I reckon the following macro will do what you want. It builds a dictionary of unique values and assigns a random colour to each, which is then matched and reused for any duplicates.

' Base function that can be used for different columns.
Sub colorDistinctInColumn(ByVal columnLetter As String)
    Dim lastRow As Integer
    Dim i As Integer
    Dim dict
    Dim currentCell As Range
    Dim columnNumber As Integer

    ' Create a dictionary to hold the value/colour pairs
    Set dict = CreateObject("Scripting.Dictionary")

    ' Find the last-used cell in the column of interest
    lastRow = ActiveSheet.Columns(columnLetter).Cells.Find( _
        "*", _
        SearchOrder:=xlByRows, _
        LookIn:=xlValues, _
        SearchDirection:=xlPrevious).Row

    ' Pick columnNumber using the given column letter
    columnNumber = ActiveSheet.Columns(columnLetter).Column

    ' Loop through all of the cells
    For i = 1 To lastRow
        Set currentCell = ActiveSheet.Cells(i, columnNumber)

        ' See if we've already come across the current value
        If Not dict.exists(currentCell.Value) Then

            ' This value has not been encountered yet,
            ' so store it and assign a random colour
            dict.Add currentCell.Value, RGB(Rnd * 255, Rnd * 255, Rnd * 255)
        End If

        ' Set the colour of the current cell to whichever colour
        ' has been stored for the current cell's value
        currentCell.Interior.Color = dict(currentCell.Value)
    Next i

    Set dict = Nothing
End Sub

' Actual Macro that will run in Excel
Sub colorDistinctInColumnA()
    Call colorDistinctInColumn("A")
End Sub